home *** CD-ROM | disk | FTP | other *** search
/ Programmer Power Tools / Programmer Power Tools.iso / printer / lptx700.arc / LPTX.ASM next >
Assembly Source File  |  1987-10-19  |  106KB  |  2,542 lines
  1. title LPTx : Line PrinTer Output Capture Routine
  2. page    60,132
  3. ;------------------------------------------------------------
  4. ;
  5. ;       MAIN PROGRAM    Version 7.00
  6. ;
  7. ;  (C)  Copyright 1987 by Mark DiVecchio, All Rights Reserved
  8. ;  (C)  Copyright 1987 by Kepa Zubeldia,  All Rights Reserved
  9. ;
  10. .xlist
  11. ;
  12. ;This program is released for use in non-commercial environments. I
  13. ;ask commercial users to register the program with a $25 copyright fee for
  14. ;each site (any number of users and computers) at which the program is used.
  15. ;
  16. ; DISCLAMER : this program tries to perform a function which is
  17. ; not supported by DOS. It will work sometime and will not work
  18. ; other times. That kind of explains why you don't see this type
  19. ; of program on the market.
  20. ; I have tested it under DOS 2.1 and DOS 3.1. Some users have
  21. ; reported trouble when running under DOS 3.x and for other users
  22. ; it works fine. USE AT YOUR OWN RISK.
  23. ;
  24. ; Mark C. DiVecchio
  25. ; 10435 Mountain Glen Terrace
  26. ; San Diego, CA 92131
  27. ; 619-566-6810
  28. ;------------------------------------------------------------
  29. ; Updates for Version 7.00               6 Oct 87
  30. ;
  31. ; Kepa Zubeldia
  32. ; Micro Consulting, Inc.
  33. ; 1650 Citizens Tower Bldg.
  34. ; Oklahoma City, OK 73106
  35. ; (405) 528-8133
  36. ;
  37. ; -Added a pop-up window that allows the control of the redirection from within
  38. ;  an application program.
  39. ; -Added a switch for monochrome screens combined with color cards, to cancel
  40. ;  the color generation and make the window more visible.
  41. ; -Deleted the Control-Z that was appended on the last close to a file.
  42. ; -Allow for file append when the program is called with the name of a file
  43. ;  that already exists. The user still has the option of overwriting the file.
  44. ; -Added a switch to perform the append automatically.
  45. ; -Corrected the -? switch so it works.
  46. ; -Assembled with Microsoft MASM V5.0
  47. ;
  48. ; The major change is the addition of the pop-up window. The code for this was
  49. ; taken from PC Magazine, October 13, 1987, page 401, a productivity utility
  50. ; written by Jeff Prosise. It works with CGA, MGA, and EGA. With the EGA it
  51. ; will also work in 120 cols. and/or 35 or 43 line modes. Exiting the pop-up
  52. ; with an EGA leaves the cursor in underline. This is not a bug, but a feature.
  53. ;
  54. ; The pop-up window lets you turn redirection on and off from within a
  55. ; running program. You first must start LPTx from the command line as
  56. ; usual :
  57. ;
  58. ; lptx output.fil
  59. ;
  60. ; Then you can press Alt-PrtSc and a pop-up window will appear. When it
  61. ; does, the up and down arrow keys select a printer and the right and
  62. ; left arrow keys select redirection. The pop-up will state "to file"
  63. ; or "to printer" indicating the state of the redirection.
  64. ;
  65. ; Press <Enter> or <Esc> to close the window.
  66. ;
  67. ; Remember that you must start LPTx from the command line before the
  68. ; pop-up will let you turn redirection on or off.
  69. ;
  70. ;------------------------------------------------------------
  71. ; Updates for Version 6.00              18 Mar 87
  72. ;
  73. ; Added use of Timer Interrupt and Idle interrupt to permit
  74. ; writing to disk
  75. ;
  76. ; Added a switch to inhibit the output of linefeed characters when
  77. ; capturing a file. Program strips linefeed character at the
  78. ; end of the line if you turn on this switch. The switch is -l on the
  79. ; command line when you open a capture file.
  80. ;
  81. ; This version does not use the PSP swapping of previous versions.
  82. ;
  83. ;------------------------------------------------------------
  84. ; Updates for Version 5.02              19 Nov 86
  85. ;
  86. ; Added -i inactivate option. Must be only option on command line :
  87. ;               lptx -i
  88. ;
  89. ; This version adds a check for DOS interuupt 21h
  90. ; function 40h for standard printer device = 0004.
  91. ;
  92. ; This addition was suggested by Dale Letterman of Seattle.
  93. ;
  94. ; Assembled using MicroSoft MASM v 4.0
  95. ;
  96. ; Program is called and used in the same way as version 3.00
  97. ;
  98. ; I now enter DOS with interrupts disabled.
  99. ;
  100. ; Added a switch to inhibit the checking of the Critical Section Flag
  101. ; Add -x to the command line the first time that you run LPTx.
  102. ;
  103. ;------------------------------------------------------------
  104. ; Updates for Version 5.00              13 May 86
  105. ;
  106. ; This version also takes over the DOS interuupt 21h and specifically
  107. ; checks for function 5.
  108. ; If that is the call, LPTx captures the character if LPTx has been
  109. ; activated. If it is a DOS call, LPTx assumes that DOS wants LPT1 since
  110. ; there is no way for the DOS call to specify a line printer number.
  111. ;
  112. ; Uses undocumented DOS int 21h calls 50h and 51h.
  113. ;       50h     Set new current Program Segment Prefix(PSP) from
  114. ;               segment number in BX
  115. ;       51h     Get current PSP into BX.
  116. ; These calls are used before any file is opened by the resident portion
  117. ; of LPTx. There is some concern that DOS puts information about open files
  118. ; into the current PSP. Before we open our spooler file, we want to set
  119. ; the current PSP to our PSP and then restore it after the file I/O
  120. ; is complete. This idea was expressed in PC Magazine May 13, 1986 on page
  121. ; 314 in an article by Charles Petzold.
  122. ;
  123. ;
  124. ; This version 5.0 does not obsolete versions 4.0 and 3.0. Those versions
  125. ; may work under some conditions where this one does not and vica versa.
  126. ;------------------------------------------------------------
  127. ; Updates for Version 4.01              5 May 86
  128. ;
  129. ; Had an error in the way LPTx detected if it was already in memory.
  130. ; This error existed from back in version 3.00 and may have been
  131. ; the cause of this program locking up the system the very first
  132. ; time it was called.
  133. ;------------------------------------------------------------
  134. ; Updates for Version 4.0               25 April 86
  135. ;
  136. ; Assembled using MicroSoft MASM v 4.0
  137. ;
  138. ; Program is called and used in the same way as version 3.00
  139. ;
  140. ; Modified the code to check if DOS was running when the print interrupt
  141. ; occurs. If so the print request is routed back to the regular line
  142. ; printer. This will limit the use of this capture program to user
  143. ; programs which do their own output without going to DOS.
  144. ;
  145. ; In turn, this guarantees that we do re-enter DOS.
  146. ;
  147. ; The trick of saving the DOS stack was dropped in this version and
  148. ; I have resorted to another trick which I garnered from the
  149. ; following message found on info-ibmpc. I use method number 2.
  150. ;
  151. ; This version 4.0 does not obsolete version 3.0. That version may
  152. ; work under some conditions where this one does not and vica versa.
  153. ; This one worked fine for me using DOS 2.1 and 123 version 1.A.
  154. ; Will not work with Shift PrtSc.
  155. ;
  156. comment *
  157. Date: Thu, 30 Jan 86 08:47:51 est
  158. Subject: File I/O from resident programs
  159. To: allegra!seismo!usc-isib.arpa!info-ibmpc
  160.  
  161. Regarding opening up a file when you are terminate-and-stay-resident:
  162.  
  163. Be very careful when you attempt this.  Many an FAT has been eaten for
  164. lunch when I first tried doing it.  Two ways that work like a charm:
  165.  
  166. 1)      Take over interrupt 0x28.  This interrupt gets called by DOS
  167.         while its waiting for a key to be hit. Whenever it does get
  168.         called (your program should not be time critical, btw, as
  169.         this routine is never called from CPU intensive tasks), it
  170.         is safe to do with DOS what you will. (Except for certain
  171.         interruptions, such as Search First and Search Next, which
  172.         either you'll screw-up for the foreground task, or they'll
  173.         screw-up for you.)
  174.  
  175. 2)      Get the Critical Section Flag by issuing an int 21, with ah=0x34.
  176.         This returns a pointer to a flag in ES:BX. When this flag is
  177.         NULL, and interrupts are on, it is safe to play DOS games.
  178.         Unless you are the last program to take over the interrupt,
  179.         don't trust the flag word: many "fine" programs like SideKick
  180.         do not give you a true copy of the flag word on the stack, but
  181.         rather give a simple "pushf" after interrupts are turned off.
  182. * ;end of comment
  183. ;
  184. ; More information from a message posted on USENIX:
  185. ;
  186. comment *
  187. From sdcsvax!ihnp4!timeinc!greenber Mon Jul  1 05:12:16 1985
  188. Date: 30 Jun 85 17:12:37 CDT (Sun)
  189. -----------------------------------------------------------
  190. INT 21 - Internal - Return CritSectFlag Pointer (MSDOS generic)
  191.           REG AH = 34H
  192.           On Return:
  193.                     ES:BX points to DOS "Critical Section Flag"
  194.           When byte pointed to is zero, DOS is supposed to be
  195.           safe to interrupt. NOT RELIABLE according to Chris
  196.           Dunford.
  197.                     Examination of DOS 2.10 code in this area
  198.           indicates that the byte immediately FOLLOWING this
  199.           "Critical Section Flag" must be 00 to permit the
  200.           PRINT.COM interrupt to be called. This suggests that
  201.           checking the WORD pointed to, rather than the BYTE,
  202.           might increase reliability of the test greatly.
  203. -----------------------------------------------------------
  204. INT 28 - Internal routine for MSDOS
  205.           This interrupt is called from inside the "get input
  206. from keyboard" routine in DOS, if and only if it is safe to use
  207. INT 21 to access the disk at that time. It is used primarily by
  208. the PRINT.COM routines, but any number of other routines could
  209. be chained to it by saving the original vector, and calling it
  210. with a FAR call (or just JMPing to it) at the end of the new
  211. routine.
  212.           Until PRINT.COM installs its own routine, this
  213. interrupt vector simply points to an IRET opcode.
  214. -----------------------------------------------------------
  215. * ;end of comment
  216. ;
  217. ;------------------------------------------------------------
  218. ; Updates for Version 3.0
  219. ;
  220. ; This version is fully compatible with IBM's PRINT command and
  221. ; hopefully most other print spoolers. I changed the method by which
  222. ; LPTx determines if a resident copy of itself is already in memory.
  223. ;
  224. ;------------------------------------------------------------
  225. ; This program intercepts the BIOS interrupt 17, the line printer
  226. ; interrupt. It will redirect the output of LPT1, LPT2, or LPT3 to a disk
  227. ; file. All three redirects may be active at the same time.
  228. ;
  229. ;
  230. ; Background:
  231. ;
  232. ; The basic problem with this type of program is that PC-DOS as written
  233. ; by Microsoft is not re-entrant. That means that if DOS is in control when
  234. ; the print interrupt occurs, you can not call DOS again to do some other
  235. ; function. Therefore, LPTx can not call DOS to write the captured print
  236. ; data to disk. Version 3.00 of LPTx tries to get around this by making
  237. ; PC-DOS re-entrant. Version 4.00 of LPTx gets around this by not ever
  238. ; trying to re-enter DOS.
  239. ;
  240. ;*******This Program Must be Converted to a .COM file before running ******
  241. ; Assemble with :
  242. ;       masm    lptx;
  243. ;       link    lptx;
  244. ;       exe2bin lptx,lptx.com
  245. ;       erase lptx.obj
  246. ;       erase lptx.exe
  247. ;
  248. ;-----------------------------------------------------------------
  249. .list
  250. if1
  251.         %out Pass 1 - Including Macros - v6.00
  252. ;
  253. .xlist
  254. ;-----------------------------------------------------------------
  255. ;
  256. ; Macros
  257. ;
  258. display macro   msg
  259.         mov     DX,offset msg
  260.         mov     AH,DISPLAY_OUTPUT
  261.         int     DOS_CALL
  262.         endm
  263. ;
  264. ; For the PC-AT:
  265. ; POPF macro described in the IBM Personal Computer
  266. ; Seminar Proceedings Volume 2, Number 4 September 1984
  267. ; QUOTE
  268. ; "If the system microprocessor executes a POPF instruction in either
  269. ; the real or the virtual address mode with CPL <= IOPL, then a 
  270. ; pending maskable interrupt (the INTR pin active) may be improperly
  271. ; recognized after executing the POPF instruction even if maskable
  272. ; interrupts were disabled before the POPF instruction and the value 
  273. ; popped had IF=0. If the interrupt is improperly recognized, the
  274. ; interrupt is still correctly executed. This errata has no effect
  275. ; when interrupts are enabled in either real or virtual address mode.
  276. ; The errata has no effect in the virtual address mode when
  277. ; CPL > IOPL."
  278. ;
  279. popff   macro                           ;use POPFF instead of POPF
  280.         local   popem,skip
  281.                                         ;simulate popping flags using IRET
  282.         jmp     short skip              ;jump around iret
  283. popem:
  284.         iret                            ;pop CS,IP,flags
  285. skip:
  286.         push    CS
  287.         call    popem                   ;call within segment
  288.                                         ;program will continue here
  289.         endm
  290.  
  291. ;
  292. call_dos        macro                   ;Enter DOS with interrupts disabled
  293.         cli
  294.         int     DOS_CALL
  295.         sti
  296.         endm
  297. ;
  298. ;
  299. .list
  300. else
  301.         %out Pass 2
  302. endif
  303. ;-----------------------------------------------------------------
  304. NULL            equ     0
  305. OFF             equ     0
  306. ON              equ     1
  307. EMPTY           equ     0
  308. BEL             equ     7
  309. CR              equ     13
  310. LF              equ     10
  311. DOLLAR          equ     '$'
  312. COLON           equ     ':'
  313. BACKSLASH       equ     '\'
  314. BLANK           equ     ' '
  315. DASH            equ     '-'
  316. DOS_CALL        equ     21h
  317. ;
  318. REQ             equ     00B91h          ;LPTx request flag
  319. ACK             equ     0ABCBh          ;LPTx acknowledge flag
  320. ;
  321. BUFSIZE         equ     4096            ;size of DMA buffer
  322. DISPLAY_OUTPUT  equ     9               ;for DOS call
  323. DEF_DRIVE       equ     19h
  324. CREATE_FILE     equ     3Ch
  325. OPEN_FILE       equ     3Dh
  326. CLOSE_FILE      equ     3Eh
  327. WRITE_FILE      equ     40h
  328. DELETE_FILE     equ     41h
  329. LSEEK_FILE      equ     42h
  330. DEF_PATH        equ     47h
  331. FIND_FILE       equ     4Eh
  332. ;-----------------------------------------------------------------
  333. ;
  334. p_block struc
  335. ;
  336. ; data structure - these variables are used only in the
  337. ; memory resident copy of LPTx. BX is set to point to the offset of the
  338. ; allocation of this structure for the selected LPT
  339. ; NOTE : all of the labels in this structure are required as place
  340. ; holders even if not referenced. Used by the initialization calls
  341. ; later on.
  342. ;
  343. active  db      OFF                     ;ON = this LPTx is on, OFF = off
  344. handle  dw      NULL                    ;handle of disk file used by this LPT
  345. filen   db      'a:\lptx'               ;space for redirection disk file name
  346. pnum    db      '0'                     ;default to '0' just in case
  347.         db      '.lst',NULL
  348.         db      '                          '
  349.         db      '                        '
  350. bufcntr dw      EMPTY                   ;bytes used in DMA buffer for this LPT
  351. request db      OFF                     ;ON indicates a write request is active
  352.                                         ;for this LPT
  353. prt_status      db      10h             ;printer status for this LPT
  354. linefeed        db      ON              ;ON = output a linefeed
  355.                                         ;OFF = don't output a linefeed
  356. buffer  db      BUFSIZE dup(0)          ;data buffer for this LPT
  357. ;
  358. p_block ends
  359. ;
  360. ;-----------------------------------------------------------------
  361. ;
  362. bios_data     segment at 40h
  363.               org 4Ah
  364. crt_cols      dw ?                          ;number of display columns
  365.               org 4Eh
  366. crt_start     dw ?                          ;video page offset address
  367.               org 63h
  368. addr_6845     dw ?                          ;CRTC base address
  369.               org 87h
  370. infobyte      label word
  371. ega_info      db ?                          ;EGA info byte
  372. bios_data     ends
  373. ;
  374. ;-----------------------------------------------------------------
  375. ;
  376. subttl  Main Code
  377. page
  378. %out Assembling CODE Segment
  379. cseg    segment para public 'CODE'
  380.         assume  CS:cseg,DS:nothing,SS:nothing
  381.         org     100h
  382. lptx:   jmp     lptx_start
  383. ;
  384. ; What follows are three allocations of the Structure p_block
  385. ; One for each line printer that we can support.
  386. ; With this, all three line printers have DMA buffers and flag
  387. ; variables.
  388. ; BX is used to point to the offset of the allocation currently in use
  389. ; Line printer 1
  390. lpt1            p_block <,,,'1'>
  391. ; Line printer 2
  392. lpt2            p_block <,,,'2'>
  393. ; Line printer 3
  394. lpt3            p_block <,,,'3'>
  395. ;
  396. crit_flag       db      OFF             ;set to ON if critical error occured
  397. off_crit        dw      0               ;save old critical error address
  398. seg_crit        dw      0
  399. ;
  400. csect_off       dw      0               ;pointer to Critical Section flag
  401. csect_seg       dw      0
  402. cerrf_off       dw      0               ;pointer to Critical Error flag
  403. cerrf_seg       dw      0
  404. ; cs_switch can be cleared by the transient copy of LPTx
  405. cs_switch       db      ON              ;enable check of Critical Section flag
  406. P_NORMAL        equ     90h             ;Printed selected and ready
  407. P_TIMEOUT       equ     01h             ;Time out
  408. save_psp        dw      0               ;Save area for User's PSP Segment Address
  409. lptx_psp        dw      0               ;Our PSP Segment Address
  410. byte_count      dw      0               ;to save DOS byte count
  411. busy            db      OFF             ;ON indicates write is taking place
  412. sound           db      OFF             ;ON uses speaker to indicate progress of LPTx
  413. ;
  414. flag_10h           db   0                   ;status of interrupt 10h
  415. flag_13h           db   0                   ;status of interrupt 13h
  416. request_popup      db   0                   ;status of processing request
  417. adapter            db   2                   ;0=MDA, 1=CGA, 2=EGA
  418. ;The following 5 lines MUST not be changed. They are dynamically set at Run Time
  419. video_segment      dw   0B800h              ;video segment address
  420. border_attr        db   ?                   ;window border attribute
  421. text_attr          db   ?                   ;window text attribute
  422. menu_attr          db   ?                   ;menu line attribute
  423. video_page         db   ?                   ;current video page
  424. cursor_mode        dw   ?                   ;cursor shape
  425. cursor_pos         dw   ?                   ;cursor position
  426. cursor_addr        dw   ?                   ;cursor CRTC address
  427. new_cursor         dw   0607h               ;Popup cursor shape
  428. nocolors           db   0                   ;monochrome only
  429. menu_choice        db   0                   ;popup cursor line (0,1,2)
  430. screen_buffer      db   48    dup('SCREEN BUFFER   ') ;10 * 34 * 2 bytes
  431. color_attr         db   0,0B8h,10h,07h,3fh  ;black/blue,white/black,hi-white/blue
  432. nocolor_attr       db   0,0B8h,70h,07h,70h  ;mono
  433. mono_attr          db   0,0B0h,70h,07h,70h
  434. enable_values      db   2Ch,28h,2Dh,29h,2Ah,2Eh,1Eh
  435. ;
  436. ; Old interrupt vector addresses
  437. old_08h dd      0                       ;address of old int 08h routine
  438. old_09h dd      0                       ;address of old int 09h routine
  439. old_10h dd      0                       ;address of old int 10h routine
  440. old_13h dd      0                       ;address of old int 13h routine
  441. old_17h dd      0                       ;address of old int 17h routine
  442. old_21h dd      0                       ;address of old int 21h routine
  443. old_28h dd      0                       ;address of old int 28h routine
  444. ;
  445. old1Bh_segment     dw ?                     ;old interrupt 1Bh segment
  446. old1Bh_offset      dw ?                     ;old interrupt 1Bh offset
  447. old23h_segment     dw ?                     ;old interrupt 23h segment
  448. old23h_offset      dw ?                     ;old interrupt 23h offset
  449. old24h_segment     dw ?                     ;old interrupt 24h segment
  450. old24h_offset      dw ?                     ;old interrupt 24h offset
  451. ;
  452. ; New Stack for Interrupt 17h
  453. stk1_save       dd      0               ;caller's stack EA
  454.                 db      128 dup('STACK   ')
  455. stk1            equ     this byte - 4
  456. ; New Stack for Interrupts 08h and 28h
  457. stk2_save       dd      0               ;caller's stack EA
  458.                 db      128 dup('STACK   ')
  459. stk2            equ     this byte - 4
  460. ; New Stack for Popup window process
  461. stk3_ss         dw      0               ;caller's stack EA
  462. stk3_sp         dw      0
  463.                 db      128 dup('STACKP  ')
  464. stk3            equ     this byte - 4
  465. ;
  466. ;------------------------------------------------------------------------------
  467. ; Window text
  468. ;------------------------------------------------------------------------------
  469. ;
  470. ;You will need an editor capable of handling graphics to edit the window.
  471. ;I used PC-Write, but old edlin will also work. 
  472. ;Do not change the width or the depth of the window !!!
  473. ;
  474. window          db "┌──────────────LPTX──────────────┐"
  475.                 db "│                                │"
  476. menuline1       db "│       lpt1:  to  PRINTER       │"
  477. menuline2       db "│       lpt2:  to  PRINTER       │"
  478. menuline3       db "│       lpt3:  to  PRINTER       │"
  479.                 db "│                                │"
  480.                 db "├────────────────────────────────┤"
  481.                 db "│ Press:  to move,  to toggle,│"
  482.                 db "│       <Enter> to close window. │"
  483.                 db "└────────────────────────────────┘"
  484. menufile1       db "│       lpt1:  to  FILE          │"
  485. menufile2       db "│       lpt2:  to  FILE          │"
  486. menufile3       db "│       lpt3:  to  FILE          │"
  487. ;------------------------------------------------------------------------------
  488. ; Interrupt handler for interrupt 09h (keyboard)
  489. ;------------------------------------------------------------------------------
  490. ;
  491. keyboard      proc near
  492.               push    ax
  493.               cmp     CS:busy,OFF           ;program already active?
  494.               jne     kb_regular            ; yes, skip processing this key.
  495.               in      al,60h                ;look at the hardware register
  496.               cmp     al,55                 ;is this PrtSc ?
  497.               jne     kb_regular            ; no, process it the old way.
  498.               sti                           ;set interrupt enable flag
  499.               mov     ah,2                  ;get keyboard shift status    
  500.               int     16h
  501.               test    al,8                  ;Alt key also pressed?
  502.               je      kb_regular            ; no, process old way.
  503.               mov     CS:request_popup,18   ;set request flag for 1 second.
  504.                                             ;now, call keyboard handling routine
  505.                                             ; to reset keyboard controller
  506.                                             ; and as courtesy to other TSRs.
  507. kb_regular:   pop     ax
  508.               jmp     dword ptr CS:old_09h
  509. keyboard      endp
  510. ;
  511. ;------------------------------------------------------------------------------
  512. ;Interrupt 10h handling routine.
  513. ;------------------------------------------------------------------------------
  514. video         proc near
  515.               pushf                         ;push flags onto stack
  516.               inc flag_10h                  ;increment flag
  517.               call dword ptr CS:old_10h     ;call BIOS routine
  518.               dec flag_10h                  ;decrement flag
  519.               iret
  520. video         endp
  521. ;
  522. ;------------------------------------------------------------------------------
  523. ;Interrupt 13h handling routine.
  524. ;------------------------------------------------------------------------------
  525. bdisk         proc far
  526.               pushf                         ;push flags onto stack
  527.               inc flag_13h                  ;set 'busy' flag
  528.               call dword ptr CS:old_13h     ;call BIOS routine
  529.               pushf                         ;save output flags
  530.               dec flag_13h                  ;clear flag
  531.               popff                         ;restore output flags
  532.               ret 2                         ;exit without destroying flags
  533. bdisk         endp
  534. ;
  535. ;
  536. ;-----------------------------------------------------------------
  537. ;
  538. ; Interrupt handler for interrupt 17h
  539. ;
  540. int_17h proc    far
  541.         sti                             ;interrupts on
  542.         cmp     AH,3                    ;AH=3 for LPTx Function
  543.         jne     reg_call                ;This is a regular print call
  544.         jmp     ret_ack                 ;This is an LPTx Call
  545. reg_call:
  546.         push    BX
  547. ; set up BX to point to the data area for the requested printer
  548.         cmp     DX,0                    ;lpt1?
  549.         jne     chk_lpt2                ;no
  550.         mov     BX,offset lpt1          ;offset to LPT1
  551.         jmp     short bx_set
  552. chk_lpt2:
  553.         cmp     DX,1                    ;lpt2?
  554.         jne     chk_lpt3                ;no
  555.         mov     BX,offset lpt2          ;offset to LPT2
  556.         jmp     short bx_set
  557. chk_lpt3:
  558.         cmp     DX,2                    ;lpt3?
  559.         jne     ill_ptr                 ;no - bad printer number
  560.         mov     BX,offset lpt3          ;offset to LPT3
  561. bx_set: 
  562.         cmp     CS:[BX].active,OFF      ;are we active?
  563.         je      sleep17                 ;no
  564.         mov     CS:[BX].prt_status,P_NORMAL     ;signal ready status
  565.         cmp     AH,1                    ;initialize call?
  566.         je      do_nix                  ;yes    
  567.         cmp     AH,2                    ;status call?
  568.         je      do_nix                  ;yes
  569.         cmp     AH,0                    ;print call?
  570.         jne     do_nix                  ;no
  571.  
  572.         jmp     prt_17                  ;we are active
  573. do_nix: mov     AH,CS:[BX].prt_status   ;return print status
  574. rtn:    pop     BX
  575.         iret
  576. ;
  577. ill_ptr:mov     CS:[BX].prt_status,P_TIMEOUT    ;time out status
  578.         jmp     do_nix
  579. ;
  580. ret_ack:                                ;return acknowledgement that I'm here
  581. ; note : Change REQ & ACK from version to version so two versions
  582. ; of LPTx don't get intermixed.
  583.         cmp     DX,REQ                  ;my flag to detect that LPTx is
  584.                                         ;already loaded and alive.
  585.         jne     ret_nak                 ;return a NAK
  586.         mov     DX,ACK                  ;Memory resident LPTx answers with ACK
  587.         push    CS                      ;now set up ES to point to the resident
  588.         pop     ES                      ; data area
  589. ret_nak:
  590.         iret                            ;return to calling program
  591. ;
  592. sleep17:pop     BX                      ;restore BX before we go to sleep
  593.         jmp     dword ptr CS:old_17h    ;jump immediate to original handler
  594. ;
  595. prt_17:
  596.         push    AX                      ; Start the print process.
  597.         push    BX                      ; Character is in AL.
  598.         push    CX
  599.         push    DX
  600.         push    DS
  601.         push    ES
  602.         push    SI
  603.         push    DI
  604.         push    BP
  605. ;
  606.         push    CS                      ; DS is used as the segment register
  607.         pop     DS                      ; for all data during the interrupt
  608. ;
  609.         pushf
  610.         cli
  611.         mov     SI,SS
  612.         mov     word ptr DS:stk1_save+2,SI      ;save caller's stack pointer
  613.         mov     SI,SP
  614.         mov     word ptr DS:stk1_save,SI
  615.         mov     SI,CS
  616.         mov     SS,SI                   ;give me new bigger stack
  617.         mov     SI,offset stk1
  618.         mov     SP,SI
  619.         popff
  620.         mov     DS:[BX].prt_status,P_NORMAL     ;signal ready status
  621.                                         ;prt_status is set before
  622.                                         ;the call to prnt so that prnt
  623.                                         ;can change it if the print to
  624.                                         ;disk fails
  625.         call    prnt                    ;print the character
  626. ;
  627.         pushf
  628.         cli
  629.         mov     SI,word ptr DS:stk1_save
  630.         mov     SP,SI                   ;restore caller's stack pointer
  631.         mov     SI,word ptr DS:stk1_save+2
  632.         mov     SS,SI
  633.         popff
  634.  
  635.         pop     BP
  636.         pop     DI
  637.         pop     SI
  638.         pop     ES
  639.         pop     DS
  640.         pop     DX
  641.         pop     CX
  642.         pop     BX
  643.         pop     AX
  644.         jmp     do_nix
  645. int_17h endp
  646. ;-----------------------------------------------------------------
  647. ;
  648. ; Interrupt handler for interrupt 21h
  649. ;
  650. int_21h proc    far
  651.         sti                             ;interrupts on
  652.         push    BX
  653.         cmp     AH,5                    ;is this a DOS printer call?
  654.         je      int_21h_5               ;yes
  655.         cmp     AH,40h                  ;is this a DOS write call?
  656.         je      int_21h_40              ;yes
  657.         jmp     sleep21                 ;no - go on to real DOS
  658. ; DOS Function 40h - Write to File or Device. DS:DX contains the address
  659. ;of data to write. CX contains the byte count. Return AX = byte count.
  660. int_21h_40:                             
  661.         cmp     BX,0004                 ;Standard Printer?
  662.         jne     sleep21                 ;no - go on to real DOS
  663. ; set up BX to point to the data area for the requested printer
  664. ; Since we don't know what the standard printer device is, we
  665. ; use LPT1
  666.         mov     BX,offset lpt1          ;offset to LPT1
  667.         cmp     CS:[BX].active,OFF      ;are we active?
  668.         je      sleep21                 ;no
  669.         push    AX                      ;now do it
  670.         push    BX
  671.         push    CX
  672.         push    DX
  673.         mov     CS:byte_count,CX        ;save byte count
  674.         mov     BX,DX
  675. ;DS:BX points to buffer, CX has byte count
  676.         cmp     CX,EMPTY                ;check for zero byte count
  677.         je      prt_21_done
  678. loop21_40:      
  679.         mov     AL,[BX]                 ;get a character
  680.         mov     AH,0                    ;set up for call to interrupt 17h
  681.         int     17h                     ;note : int17h returns a printer status
  682.                                         ;in AH but DOS does not define a way
  683.                                         ;to return that status
  684.         inc     BX
  685.         loop    loop21_40
  686. prt_21_done:
  687.         pop     DX
  688.         pop     CX
  689.         pop     BX
  690.         pop     AX
  691.         mov     AX,CS:byte_count        ;DOS returns byte count
  692.         jmp     exit21                  ;to return it to the user.
  693. ;
  694. int_21h_5:
  695. ; DOS Function 5 Printer Output. The Character in DL is output to the
  696. ; standard printer device.
  697. ;
  698. ; set up BX to point to the data area for the requested printer
  699. ; Since we don't know what the standard printer device is, we
  700. ; use LPT1
  701.         mov     BX,offset lpt1          ;offset to LPT1
  702.         cmp     CS:[BX].active,OFF      ;are we active?
  703.         je      sleep21                 ;no
  704.  
  705.         push    AX
  706.         mov     AH,0                    ;set up for call to interrupt 17h
  707.         mov     AL,DL                   ;the character
  708.         int     17h
  709.         pop     AX
  710.                                         ;note : int17h returns a printer status
  711.                                         ;in AH but DOS does not define a way
  712.                                         ;to return it to the user.
  713. exit21: pop     BX
  714.         popff                           ;restore flags
  715.         clc                             ;never an error from us
  716.         ret                             ;return to caller (regular FAR return)
  717. ;
  718. sleep21:pop     BX                      ;restore BX before we go to sleep
  719.         jmp     dword ptr CS:old_21h
  720. int_21h endp
  721. ;
  722. ;-----------------------------------------------------------------
  723. ;
  724. ; PRNT - Print a character in AL
  725. ;
  726. prnt    proc    near
  727.         push    DS
  728.         cmp     DS:[BX].active,OFF
  729.         je      prtext                  ;nothing there?
  730.         push    AX
  731.         cmp     DS:[BX].bufcntr,BUFSIZE/2       ;buffer half full?
  732.         jne     intadd                  ;no
  733. ;
  734. ; set write request but don't actually write anything out.
  735. ; we hope that the write can take place before the buffer fills up
  736. ;
  737.         mov     DS:[BX].request,ON
  738.         cmp     DS:sound,OFF            ;sound on?
  739.         je      intadd                  ;no
  740.         call    horn                    ;sound horn to indicate buffer
  741.                                         ; write request has been made
  742. ;
  743. intadd: pop     AX
  744.         cmp     AL,LF                   ;is it a linefeed?
  745.         jne     intnolf                 ;no
  746.         cmp     DS:[BX].linefeed,OFF    ;we are stripping linefeeds?
  747.         je      prtext                  ;yes
  748. intnolf:
  749.         mov     DI,BX                   ;offset of this printer's allocation
  750.         add     DI,offset lpt1.buffer   ;add in offset of buffer
  751.         add     DI,DS:[BX].bufcntr      ;add in current byte count
  752.         mov     DS:[DI],AL              ;stuff it
  753.         inc     DS:[BX].bufcntr
  754.         cmp     DS:[BX].bufcntr,BUFSIZE ;buffer overflow?
  755.         jne     prtext                  ;no
  756.         mov     DS:[BX].active,OFF      ;yes, nothing to do but deactivate
  757.                                         ; LPTx
  758.         cmp     DS:sound,OFF            ;sound on?
  759.         je      prtext                  ;no
  760.         call    beep                    ;sound beep twice to indicate that
  761.         call    beep                    ;we have been deactivated
  762. prtext: pop     DS
  763.         ret                             ;done
  764. prnt    endp
  765. ;-----------------------------------------------------------------
  766. ;
  767. ; Critical Error Handler
  768. ;
  769. crit_int        proc    far             ;got critical error
  770.         mov     CS:crit_flag,ON         ; set flag
  771.         mov     AL,0                    ;tells DOS to ignore the
  772.         iret                            ;error
  773. crit_int        endp
  774. ;-----------------------------------------------------------------
  775. ;
  776. ; Interrupt handler for interrupt 08h - clock ticks
  777. ;
  778. ; This function is installed as a handler for hardware interrupt
  779. ; type 8. It first calls the previous int 08h handler to service
  780. ; the INTEL 8259 Programmable Interrupt Controller. Then it checks
  781. ; to see if any write requests are pending. If so, it calls do_save
  782. ; and flush to write the buffer to the disk. Note that int_08h
  783. ; checks the DOS critical section flag : do_save is called only if
  784. ; DOS is available.
  785. ;
  786. ; This function protects itself against secondary invocations by
  787. ; means of the global busy flag.
  788. ;
  789. int_08h proc    far
  790. ; call original int 8h handler - ALWAYS
  791.         pushf
  792.         call    dword ptr CS:old_08h
  793. ; now we can process if possible
  794.         pushf
  795.         cli
  796.         cmp     CS:busy,OFF             ;can we process this?
  797.         jne     i08_exit                ;no
  798.         cmp     CS:flag_10h,0           ;video flag set?
  799.         jne     dectime                 ;yes, then exit
  800.         cmp     CS:flag_13h,0           ;disk flag set?
  801.         jne     dectime                 ;yes, then exit
  802. ; if DOS is in its critical section, we skip the write for now and
  803. ; hope that we can write before the buffer fills
  804.         push    DS                      ; check the critical section flag
  805.         push    SI
  806.         push    BX
  807.         cmp     CS:cs_switch,OFF        ;is checking off?
  808.         je      no_cs                   ;yes, don't check the flag
  809.         lds     SI,dword ptr CS:csect_off
  810.         cmp     byte ptr [SI],OFF
  811.         jne     poptime                 ;DOS in critical section
  812.                                         ;this indicates that we cannot
  813.                                         ;do any disk operations at this
  814.                                         ;time
  815.         lds     SI,dword ptr CS:cerrf_off
  816.         cmp     byte ptr [SI],OFF
  817.         jne     poptime                 ;DOS in critical error
  818.                                         ;this indicates that we cannot
  819.                                         ;do any disk operations at this
  820.                                         ;time
  821. no_cs:
  822.         cmp     CS:request_popup,0
  823.         je      no_popup
  824.         call    do_popup
  825. no_popup:
  826.         mov     BX,offset lpt1          ;offset to LPT1
  827.         cmp     DS:[BX].request,ON      ;write LPT1 request?
  828.         jne     no_lpt1                 ;no
  829.         call    do_save
  830. no_lpt1:
  831.         mov     BX,offset lpt2          ;offset to LPT2
  832.         cmp     DS:[BX].request,ON      ;write LPT2 request?
  833.         jne     no_lpt2                 ;no
  834.         call    do_save
  835. no_lpt2:
  836.         mov     BX,offset lpt3          ;offset to LPT3
  837.         cmp     DS:[BX].request,ON      ;write LPT3 request?
  838.         jne     poptime                 ;no
  839.         call    do_save
  840. poptime:
  841.         pop     BX
  842.         pop     SI
  843.         pop     DS
  844. dectime:
  845.         cmp     request_popup,0
  846.         je      i08_exit
  847.         dec     request_popup
  848. i08_exit:
  849.         popff
  850.         iret
  851.  
  852. int_08h endp
  853. ;-----------------------------------------------------------------
  854. ;
  855. ; Interrupt handler for interrupt 28h - idle
  856. ;
  857. ; This function is installed as a handler for hardware interrupt
  858. ; type 28h. It first calls the previous int 28h handler. Then it checks
  859. ; to see if any write requests are pending. If so, it calls do_save
  860. ; and flush to write the buffer to the disk. It does not check the
  861. ; Critical Section Flag as int 28h handlers are allowed to perform
  862. ; DOS disk I/O but not keyboard I/O since most of the time int 28h
  863. ; is called by the keyboard I/O routines when they are waiting
  864. ; for a key press.
  865. ;
  866. ; This function protects itself against secondary invocations by
  867. ; means of the global busy flag.
  868. ;
  869. int_28h proc    far
  870. ; call original int 28h handler - ALWAYS
  871.         pushf
  872.         call    dword ptr CS:old_28h
  873. ; now we can process if possible
  874.         pushf
  875.         cli
  876.         cmp     CS:busy,OFF             ;can we process this?
  877.         jne     i28_exit                ;no
  878.         cmp     CS:flag_10h,0           ;video flag set?
  879.         jne     i28_exit                ;yes, then exit
  880.         cmp     CS:flag_13h,0           ;disk flag set?
  881.         jne     i28_exit                ;yes, then exit
  882.         cmp     CS:cs_switch,OFF        ;is checking off?
  883.         je      i28_no_cs               ;yes, don't check the flag
  884.         push    DS
  885.         push    SI
  886.         lds     SI,dword ptr CS:cerrf_off
  887.         cmp     byte ptr [SI],OFF
  888.         pop     SI
  889.         pop     DS
  890.         jne     i28_exit                ;DOS in critical error
  891.                                         ;this indicates that we cannot
  892.                                         ;do any disk operations at this
  893.                                         ;time
  894. i28_no_cs:
  895.         cmp     CS:request_popup,0
  896.         je      i28_nopopup
  897.         call    do_popup
  898. i28_nopopup:
  899.         call    do_save
  900. i28_exit:
  901.         popff
  902.         iret
  903. int_28h endp
  904. ;-----------------------------------------------------------------
  905. ;
  906. do_popup proc   near
  907.         mov     CS:busy,ON
  908.         mov     CS:request_popup,0
  909.         cli
  910.         mov     CS:stk3_ss,SS
  911.         mov     CS:stk3_sp,SP
  912.         push    cs
  913.         pop     ss
  914.         mov     sp,offset stk3
  915.         sti                             ;interrupts on
  916.         push    AX                      ; Save everything
  917.         push    BX
  918.         push    CX
  919.         push    DX
  920.         push    DS
  921.         push    ES
  922.         push    SI
  923.         push    DI
  924.         push    BP
  925.         pushf
  926. ;
  927.               mov ah,15                     ;get video mode and page
  928.               int 10h
  929.               cmp al,3                      ;mode 0, 1, 2, or 3?
  930.               jbe pu_main1                  ;yes, then continue
  931.               cmp al,7                      ;mode 7?
  932.               je pu_main1                   ;yes, then continue
  933.                                             ;no, we must be in graphics, and
  934.                                             ;I don't know how to open a window
  935.                                             ;while in graphics...
  936. ;
  937. ;Restore registers and stack before exit.
  938. ;
  939. do_pop_exit:
  940.         popff
  941.         pop     BP
  942.         pop     DI
  943.         pop     SI
  944.         pop     ES
  945.         pop     DS
  946.         pop     DX
  947.         pop     CX
  948.         pop     BX
  949.         pop     AX
  950.         cli
  951.         mov     ss,CS:stk3_ss
  952.         mov     sp,CS:stk3_sp
  953.         sti                             ;interrupts on
  954.         mov     CS:busy,OFF
  955.         ret
  956. ;
  957. ;Set DS and ES segment registers.
  958. ;
  959. pu_main1:     push cs                       ;set DS to code segment
  960.               pop ds
  961.               assume ds:cseg
  962.               mov ax,bios_data              ;point ES to BIOS data
  963.               mov es,ax
  964.               assume es:bios_data
  965.               cmp crt_cols,80               ;at least 80 columns displayed?
  966.               jb do_pop_exit                ;no, then exit
  967. ;
  968. ;Save needed video parameters.
  969. ;
  970.               mov video_page,bh             ;active video page
  971.               mov ah,3                      ;get cursor mode and location
  972.               int 10h
  973.               mov cursor_mode,cx
  974.               mov cursor_pos,dx
  975.               mov dx,addr_6845              ;get CRTC base address
  976.               push dx                       ;save it for later
  977.               mov al,14                     ;specify register number
  978.               out dx,al
  979.               inc dx                        ;point DX to data port
  980.               in al,dx                      ;read high byte of address
  981.               mov ah,al                     ;save it
  982.               dec dx                        ;back to index register
  983.               mov al,15                     ;specify register number
  984.               out dx,al
  985.               inc dx                        ;back to data port
  986.               in al,dx                      ;read low byte of address
  987.               mov cursor_addr,ax            ;save cursor address
  988. ;
  989. ;Determine whether an EGA is present and active in the system.
  990. ;
  991.               mov ah,12h                    ;see if EGA is present
  992.               mov bl,10h
  993.               int 10h
  994.               cmp bl,10h                    ;did BL return unchanged?
  995.               je pu_main2                   ;yes, then there's no EGA here
  996.               test ega_info,8               ;is the EGA currently active?
  997.               jnz pu_main2                  ;no, then branch
  998.               mov adapter,2                 ;set ADAPTER for EGA
  999.               push bx                       ;save BX
  1000.               mov ax,1130h                  ;get number of scan lines per char
  1001.               int 10h
  1002.               dec cl                        ;form cursor definition in CX
  1003.               mov ch,cl
  1004.               sub ch,2
  1005.               mov new_cursor,cx             ;save cursor definition
  1006.               mov si,offset color_attr      ;point SI to color parms
  1007.               pop bx                        ;retrieve BX
  1008.               or bh,bh                      ;EGA attached to color monitor?
  1009.               je pu_hascolor                ;yes, then branch
  1010.               mov si,offset mono_attr       ;no, then point SI to mono parms
  1011.               jmp short pu_main4
  1012. pu_hascolor:  cmp nocolors,0                ;use monochrome only ?
  1013.               je pu_main4                   ; no, use color
  1014.               mov si,offset nocolor_attr    ;color card with mono screen
  1015.               jmp short pu_main4
  1016. ;
  1017. ;Determine whether the active video adapter is a CGA or an MDA.
  1018. ;
  1019. pu_main2:     test addr_6845,40h            ;is bit 6 of the CRTC address set?
  1020.               jz pu_main3                   ;no, then it's monochrome
  1021.               mov adapter,1                 ;set ADAPTER for a CGA
  1022.               mov new_cursor,0607h          ;define cursor shape
  1023.               mov si,offset color_attr      ;point SI to color parms
  1024.               jmp short pu_hascolor
  1025. pu_main3:     mov adapter,0                 ;set ADAPTER for an MDA
  1026.               mov new_cursor,0B0Ch          ;define monochrome cursor
  1027.               mov si,offset mono_attr       ;point SI to mono parms
  1028. ;
  1029. ;Set video parameters for color or monochrome.
  1030. ;
  1031. pu_main4:     push cs                       ;set ES to the code segment
  1032.               pop es
  1033.               assume es:cseg
  1034.               mov di,offset video_segment   ;point DI to destination
  1035.               mov cx,5                      ;5 bytes to move
  1036.               cld                           ;clear DF
  1037.               rep movsb                     ;transfer the values
  1038. ;
  1039.               cmp adapter,1                 ;disable CGA video
  1040.               jne pu_main7
  1041.               call disable_cga
  1042. pu_main7:     call save_screen              ;save memory to be overwritten
  1043.               call make_screen              ;open the Pop-up window
  1044.               call make_status              ;update status of the redirection
  1045.               cmp adapter,1                 ;enable CGA video
  1046.               jne pu_main8
  1047.               call enable_cga
  1048. pu_main8:     mov ah,1                      ;hide the cursor
  1049.               mov ch,20h
  1050.               int 10h
  1051. ;
  1052. ;Wait for a keystroke and return when ESC is pressed.
  1053. ;
  1054. pu_mainA:     call getkey                   ;wait for a keypress
  1055.               or al,al                      ;extended code entered?
  1056.               je pu_main12                  ;yes, then branch
  1057.               cmp al,32                     ;SPACE pressed?
  1058.               je toggle                     ;yes, toggle line
  1059.               cmp al,13                     ;ENTER pressed?
  1060.               je escape                     ;yes, then get out
  1061.               cmp al,27                     ;ESC pressed?
  1062.               je escape                     ;yes, then close window and return
  1063.               jmp pu_mainA                  ;no, then ignore keypress
  1064. ;
  1065. ;An extended code was entered.  Check for an Alt-character key combination.
  1066. ;
  1067. pu_main12:    cmp ah,72                     ;UpArrow?
  1068.               je upone                      ;yes, then process it
  1069.               cmp ah,80                     ;DownArrow?
  1070.               je downone                    ;yes, then process it
  1071.               cmp ah,75                     ;LeftArrow?
  1072.               je toggle                     ;toggle line
  1073.               cmp ah,77                     ;RightArrow?
  1074.               je toggle                     ;toggle line
  1075.               jmp pu_mainA                  ;return for another keypress
  1076. ;
  1077. upone:        cmp menu_choice,0             ;are we at the top ?
  1078.               jne upone1                    ; no, decrement it
  1079.               mov menu_choice,3             ; yes, wrap around
  1080. upone1:       dec menu_choice
  1081.               call make_status              ;update status of the redirection
  1082.               jmp pu_mainA
  1083.  
  1084. downone:      cmp menu_choice,2             ;are we at the bottom ?
  1085.               jne downone1                  ; no, increment
  1086.               mov menu_choice,-1            ; yes, wrap around
  1087. downone1:     inc menu_choice
  1088.               call make_status              ;update status of the redirection
  1089.               jmp pu_mainA
  1090.  
  1091. toggle:       call make_change             ;change the state
  1092.               call make_status              ;update status of the redirection
  1093.               jmp pu_mainA
  1094. ;
  1095. ;Close the Pop-up window in preparation for return.
  1096. ;
  1097. escape:       
  1098.               cmp adapter,1                 ;disable CGA video
  1099.               jne esc1
  1100.               call disable_cga
  1101. esc1:         call restore_screen           ;restore screen contents
  1102.               cmp adapter,1                 ;enable CGA video
  1103.               jne esc2
  1104.               call enable_cga
  1105. ;
  1106. ;Restore the cursor's former position in the BIOS data area and the CRTC.
  1107. ;
  1108. esc2:         mov ah,2                      ;set cursor position thru BIOS
  1109.               mov bh,video_page
  1110.               mov dx,cursor_pos
  1111.               int 10h
  1112.               pop dx                        ;recover CRTC base address
  1113.               mov cx,cursor_addr            ;restore cursor address
  1114.               mov al,14                     ;CRTC register number
  1115.               out dx,al
  1116.               inc dx
  1117.               mov al,ch
  1118.               out dx,al                     ;write high byte of address
  1119.               dec dx
  1120.               mov al,15                     ;CRTC register number
  1121.               out dx,al
  1122.               inc dx
  1123.               mov al,cl
  1124.               out dx,al                     ;write low byte
  1125. ;
  1126. ;Display the cursor, bypassing EGA cursor emulation logic, and return.
  1127. ;
  1128.               cmp adapter,2                 ;EGA on board?
  1129.               jne esc3                      ;no, then branch
  1130.               call show_cursor              ;retain current shape
  1131.               jmp do_pop_exit               ; exit from popup
  1132. esc3:         mov ah,1                      ;restore cursor shape
  1133.               mov cx,cursor_mode
  1134.               int 10h
  1135.               jmp do_pop_exit               ; exit from popup
  1136. do_popup endp
  1137. ;
  1138. ;------------------------------------------------------------
  1139. ;
  1140. ; Writes buffer to disk
  1141. ;
  1142. do_save proc    near
  1143.         mov     CS:busy,ON              ; set busy flag
  1144.         push    AX                      ; Start the print process.
  1145.         push    BX                      ; Character is in AL.
  1146.         push    CX
  1147.         push    DX
  1148.         push    DS
  1149.         push    ES
  1150.         push    SI
  1151.         push    DI
  1152.         push    BP
  1153.         pushf
  1154.         sti                             ;interrupts on
  1155. ;
  1156.         push    CS                      ; DS is used as the segment register
  1157.         pop     DS                      ; for all data during the interrupt
  1158. ;
  1159.         pushf
  1160.         cli
  1161.         mov     SI,SS
  1162.         mov     word ptr DS:stk2_save+2,SI      ;save caller's stack pointer
  1163.         mov     SI,SP
  1164.         mov     word ptr DS:stk2_save,SI
  1165.         mov     SI,CS
  1166.         mov     SS,SI                   ;give me new bigger stack
  1167.         mov     SI,offset stk2
  1168.         mov     SP,SI
  1169.         popff
  1170. ;
  1171. ; check to see if any write requests are active.
  1172. ; we do not look at the active flag since the print redirection
  1173. ; may have been inactivated by the time, we are able to write to
  1174. ; the disk.
  1175. ;
  1176. ; set up BX to point to the data area for the requested printer
  1177.         mov     BX,offset lpt1          ;offset to LPT1
  1178.         cmp     DS:[BX].request,ON      ;write LPT1 request?
  1179.         jne     c28_lpt2                ;no
  1180.         call    flush
  1181.         mov     DS:[BX].request,OFF
  1182. c28_lpt2:
  1183.         mov     BX,offset lpt2          ;offset to LPT2
  1184.         cmp     DS:[BX].request,ON      ;write LPT2 request?
  1185.         jne     c28_lpt3                ;no
  1186.         call    flush
  1187.         mov     DS:[BX].request,OFF
  1188. c28_lpt3:
  1189.         mov     BX,offset lpt3          ;offset to LPT3
  1190.         cmp     DS:[BX].request,ON      ;write LPT3 request?
  1191.         jne     i28_done                ;no
  1192.         call    flush
  1193.         mov     DS:[BX].request,OFF
  1194. i28_done:
  1195.         pushf
  1196.         cli
  1197.         mov     SI,word ptr DS:stk2_save
  1198.         mov     SP,SI                   ;restore caller's stack pointer
  1199.         mov     SI,word ptr DS:stk2_save+2
  1200.         mov     SS,SI
  1201.         popff
  1202. ;
  1203.         popff
  1204.         pop     BP
  1205.         pop     DI
  1206.         pop     SI
  1207.         pop     ES
  1208.         pop     DS
  1209.         pop     DX
  1210.         pop     CX
  1211.         pop     BX
  1212.         pop     AX
  1213.         mov     CS:busy,OFF
  1214.         ret
  1215. do_save endp
  1216. ;
  1217. ;------------------------------------------------------------
  1218. ;
  1219. ; FLUSH - Flush print buffer to disk file
  1220. ;
  1221. flush   proc    near
  1222.         cmp     DS:[BX].bufcntr,EMPTY   ;buffer empty?
  1223.         jne     flush_buf               ;no, write it to disk
  1224.         ret                             ;exit
  1225. flush_buf:
  1226.         call    disk_out
  1227.         ret
  1228. flush   endp
  1229. ;------------------------------------------------------------
  1230. ;
  1231. ; DISK_OUT - write to disk
  1232. ;
  1233. disk_out        proc    near
  1234. ;PSP
  1235. ;       push    BX
  1236. ;       mov     AH,51h                  ;get current PSP
  1237. ;       call_dos
  1238. ;       mov     DS:save_psp,BX          ;and save it
  1239. ;       mov     BX,DS:lptx_psp          ;get our PSP
  1240. ;       mov     AH,50h
  1241. ;       call_dos                        ;set it into DOS
  1242. ;       pop     BX
  1243. ;
  1244.         push    ES
  1245.         push    DS
  1246.         mov     AX,DS                   ;set up ES
  1247.         mov     ES,AX
  1248.         push    BX
  1249.         push    ES
  1250.         mov     AX,3524h                ;get old critical error vector
  1251.         call_dos
  1252.         mov     DS:off_crit,BX
  1253.         mov     DS:seg_crit,ES
  1254.         mov     DX,offset crit_int
  1255.         mov     AX,2524h        
  1256.         call_dos                        ;trap critical error vector
  1257.         mov     DS:crit_flag,OFF        ;clear critical error flag
  1258.         pop     ES
  1259.         pop     BX
  1260.         mov     DX,BX                   ;open file
  1261.         add     DX,offset lpt1.filen    ;filename
  1262.         mov     AL,1                    ;open for writing
  1263.         mov     AH,open_FILE
  1264.         call_dos
  1265.         mov     DS:[BX].handle,AX       ;file handle
  1266.         jc      disk_err                ;error
  1267.         cmp     DS:crit_flag,ON         ;critical error?
  1268.         je      disk_err                ;yes
  1269.         push    BX
  1270.         mov     AH,lseek_FILE
  1271.         mov     AL,2                    ;end of file
  1272.         mov     CX,0                    ;offset 0
  1273.         mov     DX,0
  1274.         mov     BX,DS:[BX].handle
  1275.         call_dos
  1276.         pop     BX
  1277.         jc      disk_err                ;some seek error
  1278.         cmp     DS:crit_flag,ON         ;critical error?
  1279.         je      disk_err                ;yes
  1280.         mov     CX,DS:[BX].bufcntr      ;buffer size
  1281.         mov     DX,BX                   ;offset of structure allocation
  1282.         add     DX,offset lpt1.buffer   ;add offset of buffer within the
  1283.                                         ;       allocation
  1284.         push    BX
  1285.         mov     AH,write_FILE
  1286.         mov     BX,DS:[BX].handle       ;file handle
  1287.         call_dos                        ;buffer address is DS:DX
  1288.         pop     BX
  1289.         jnc     disk_ok
  1290.         cmp     DS:crit_flag,ON         ;critical error?
  1291.         je      disk_err                ;yes
  1292.         cmp     AX,DS:[BX].bufcntr      ;did DOS write it all?
  1293.         je      disk_ok                 ;yes
  1294. disk_err:
  1295.         call    beep                    ;ring bell 4 times
  1296.         call    beep
  1297.         call    beep
  1298.         call    beep
  1299.         mov     DS:[BX].active,OFF      ;turn us off
  1300.         mov     DS:crit_flag,OFF        ;clear error flag
  1301.         mov     DS:[BX].prt_status,P_TIMEOUT    ;signal time out error
  1302.                                         ;then try to close the file
  1303.                                         ;to save what we can
  1304.         jmp     disk_close
  1305. disk_ok:
  1306.         mov     DS:[BX].bufcntr,EMPTY   ;set buffer empty
  1307. disk_close:
  1308.         push    BX
  1309.         mov     BX,DS:[BX].handle
  1310.         mov     AH,close_FILE           ;close the file
  1311.         call_dos
  1312.         pop     BX
  1313. disk_exit:
  1314.         pop     DS
  1315.         pop     ES
  1316.         push    DS
  1317.         lds     DX,dword ptr DS:off_crit
  1318.         mov     AX,2524h                ;restore critical error vector
  1319.         call_dos
  1320.         pop     DS
  1321. ; PSP
  1322. ;       push    BX
  1323. ;       mov     BX,DS:save_psp          ;get user's PSP
  1324. ;       mov     AH,50h
  1325. ;       call_dos                        ;set it back into DOS
  1326. ;       pop     BX
  1327. ;
  1328.         ret
  1329. disk_out        endp
  1330. ;
  1331. ;--------------------------------------------------------------
  1332. ; 
  1333. ; Routine to sound the beeper
  1334. ;
  1335. note            equ     0a98h           ;2712 = 1193180. / 440Hz
  1336. beep    proc    near
  1337.         push    AX
  1338.         push    BX
  1339.         push    CX
  1340.         push    DX
  1341.         mov     AL,0b6h                 ;select tim 2,lsb,msb,binary
  1342.         out     43h,AL                  ;set up timer chip
  1343.         mov     AX,note                 ;get note
  1344.         out     42h,AL                  ;write timer 2 count:  lsb...
  1345.         mov     AL,AH
  1346.         out     42h,AL                  ;...and msb
  1347.         in      AL,61h
  1348.         mov     AH,AL                   ;save current port setting
  1349.         or      AL,3
  1350.         out     61h,AL                  ;turn speaker on
  1351.         mov     CX,07FFFh
  1352. beep_lp:loop    beep_lp
  1353.         mov     AL,AH
  1354.         out     61h,AL                  ;restore port setting
  1355.         mov     CX,03FFFh
  1356. beep1_lp:loop   beep1_lp
  1357.         pop     DX
  1358.         pop     CX
  1359.         pop     BX
  1360.         pop     AX
  1361.         ret                             ;return to caller
  1362. beep    endp
  1363. ;-------------------------------------------------------------------
  1364. ; 
  1365. ; Routine to sound a key click
  1366. ;
  1367. key_clk         equ     036h            ;59 = 1193180. / 20,000Hz
  1368. click   proc    near
  1369.         push    AX
  1370.         push    BX
  1371.         push    CX
  1372.         mov     AL,0b6h                 ;select tim 2,lsb,msb,binary
  1373.         out     43h,AL                  ;set up timer chip
  1374.         mov     AX,key_clk              ;get note
  1375.         out     42h,AL                  ;write timer 2 count:  lsb...
  1376.         mov     AL,AH
  1377.         out     42h,AL                  ;...and msb
  1378.         in      AL,61h
  1379.         mov     AH,AL                   ;save current port setting
  1380.         or      AL,3
  1381.         out     61h,AL                  ;turn speaker on
  1382.         mov     CX,0FFh
  1383. key_lp:loop     key_lp
  1384.         mov     AL,AH
  1385.         out     61h,AL                  ;restore port setting
  1386.         mov     CX,0FFh
  1387. key1_lp:loop    key1_lp
  1388.         pop     CX
  1389.         pop     BX
  1390.         pop     AX
  1391.         ret                             ;return to caller
  1392. click   endp
  1393. ;--------------------------------------------------------------
  1394. ; 
  1395. ; Routine to honk the horn
  1396. ;
  1397. horn    proc    near
  1398.         push    AX
  1399.         push    BX
  1400.         push    CX
  1401.         push    DX
  1402.         mov     AL,0b6h                 ;select tim 2,lsb,msb,binary
  1403.         out     43h,AL                  ;set up timer chip
  1404.         mov     AX,2e9bh                ;2712 = 1193180. / 100Hz
  1405.         out     42h,AL                  ;write timer 2 count:  lsb...
  1406.         mov     AL,AH
  1407.         out     42h,AL                  ;...and msb
  1408.         in      AL,61h
  1409.         mov     AH,AL                   ;save current port setting
  1410.         or      AL,3
  1411.         out     61h,AL                  ;turn speaker on
  1412.         mov     CX,07FFFh
  1413. horn_lp:loop    horn_lp
  1414.         mov     AL,AH
  1415.         out     61h,AL                  ;restore port setting
  1416.         mov     CX,03FFFh
  1417. horn1_lp:loop   horn1_lp
  1418.         pop     DX
  1419.         pop     CX
  1420.         pop     BX
  1421.         pop     AX
  1422.         ret                             ;return to caller
  1423. horn    endp
  1424. ;--------------------------------------------------------------------
  1425.  
  1426. ;------------------------------------------------------------------------------
  1427. ;SAVE_SCREEN saves the contents of the screen that underlie the window.
  1428. ;------------------------------------------------------------------------------
  1429. video_address dw ?                          ;video address
  1430. linesum       dw ?
  1431. ;
  1432. save_screen   proc near
  1433.               push ds                       ;save DS
  1434.               mov ax,bios_data              ;point it to BIOS data area
  1435.               mov ds,ax
  1436.               assume ds:bios_data
  1437.               mov ax,crt_cols               ;get number of display columns
  1438.               mov linesum,ax                ;calculate distance from end of
  1439.               sub linesum,34                ;  one line to start of next
  1440.               shl linesum,1                 ;  accounting for attribute bytes
  1441.               mov bl,6                      ;calculate starting addrss (6 lines)
  1442.               mul bl                        ;result in AX
  1443.               add ax,18                     ;add line offset (18 columns)
  1444.               shl ax,1                      ;double result for attr bytes
  1445.               mov si,ax                     ;transfer to SI
  1446.               add si,crt_start              ;add page offset
  1447.               mov video_address,si          ;save offset address
  1448.               mov ds,video_segment          ;then set DS to the video segment
  1449.               mov di,offset screen_buffer   ;point DI to storage buffer
  1450.               mov cx,10                     ;10 lines to save
  1451. save_screen1: push cx                       ;save line count
  1452.               mov cx,34                     ;34 characters per line
  1453.               rep movsw                     ;transfer one line to storage
  1454.               pop cx                        ;retrieve line count
  1455.               add si,linesum                ;point SI to next video line
  1456.               loop save_screen1             ;loop until all lines are saved
  1457.               pop ds                        ;restore DS
  1458.               assume ds:cseg
  1459.               ret                           ;exit
  1460. save_screen   endp
  1461. ;
  1462. ;------------------------------------------------------------------------------
  1463. ;RESTORE_SCREEN writes the stored screen image to video memory.
  1464. ;------------------------------------------------------------------------------
  1465. restore_screen proc near
  1466.               push es                       ;save ES register value
  1467.               mov di,video_address          ;point DI to starting video offset
  1468.               mov es,video_segment          ;point ES to video memory
  1469.               mov si,offset screen_buffer   ;point DS:SI to screen image
  1470.               mov cx,10                     ;10 lines to restore
  1471. restore1:     push cx                       ;save line count
  1472.               mov cx,34                     ;34 characters per line
  1473.               rep movsw                     ;restore one line
  1474.               pop cx                        ;retrieve line count
  1475.               add di,linesum                ;set DI to next video line
  1476.               loop restore1                 ;loop until done
  1477.               pop es                        ;restore ES
  1478.               ret
  1479. restore_screen endp
  1480. ;
  1481. ;------------------------------------------------------------------------------
  1482. ;MAKE_SCREEN writes an image of the Pop-up window to video memory.
  1483. ;------------------------------------------------------------------------------
  1484. make_screen   proc near
  1485.               push es                       ;save ES
  1486.               mov es,video_segment          ;point ES:DI to video memory
  1487.               mov di,video_address
  1488.               mov si,offset window          ;line 1
  1489.               mov cx,34                     ;do 34 characters
  1490.               mov ah,border_attr            ;this makes the top border
  1491. make0:        lodsb
  1492.               stosw
  1493.               loop make0
  1494.               add di,linesum
  1495.               mov cx,5                      ;5 lines of user text
  1496. make1:        push cx
  1497.               call formline
  1498.               add di,linesum
  1499.               pop cx
  1500.               loop make1
  1501.               mov cx,4                      ;4 lines of instructions on bottom
  1502.               mov ah,border_attr
  1503. make2:        push cx
  1504.               mov cx,34                     ;do next 34 characters
  1505. make3:        lodsb
  1506.               stosw
  1507.               loop make3
  1508.               add di,linesum
  1509.               pop cx
  1510.               loop make2
  1511.               pop es                        ;restore ES
  1512.               ret
  1513. make_screen   endp
  1514. ;
  1515. ;------------------------------------------------------------------------------
  1516. ;MAKE_STATUS writes the new status of the redirection window to video memory.
  1517. ;------------------------------------------------------------------------------
  1518. make_status   proc near
  1519.               push es                       ;save ES
  1520.               mov es,video_segment          ;point ES:DI to video memory
  1521.               mov di,video_address          ;this point to the beginning of w.
  1522.               add di,34 * 2                 ;skip over the text
  1523.               add di,linesum                ;skip to next line
  1524.               add di,34 * 2                 ;skip over the text
  1525.               add di,linesum                ;go down one line
  1526.  
  1527.               cmp adapter,1                 ;disable CGA video
  1528.               jne msts0
  1529.               call disable_cga
  1530. msts0:
  1531.               mov bx,offset lpt1            ;structure #1
  1532.               cmp ds:[bx].active,OFF        ;printer redirected ?
  1533.               mov si,offset menuline1       ; no, text says PRINTER
  1534.               je msts1
  1535.               mov si,offset menufile1       ; yes, text says FILE
  1536. msts1:        cmp menu_choice,0             ;is this the highlighted choice?
  1537.               je msts2
  1538.               call formline                 ; no, display normal
  1539.               jmp short msts3
  1540. msts2:        call cursline                 ; yes, display highlighted
  1541. msts3:        add di,linesum                ;go down one line
  1542.  
  1543.               mov bx,offset lpt2            ;structure #2
  1544.               cmp ds:[bx].active,OFF        ;printer redirected ?
  1545.               mov si,offset menuline2       ; no, text says PRINTER
  1546.               je msts4
  1547.               mov si,offset menufile2       ; yes, text says FILE
  1548. msts4:        cmp menu_choice,1             ;is this the highlighted choice?
  1549.               je msts5
  1550.               call formline                 ; no, display normal
  1551.               jmp short msts6
  1552. msts5:        call cursline                 ; yes, display highlighted
  1553. msts6:        add di,linesum                ;go down one line
  1554.  
  1555.               mov bx,offset lpt3            ;structure #3
  1556.               cmp ds:[bx].active,OFF        ;printer redirected ?
  1557.               mov si,offset menuline3       ; no, text says PRINTER
  1558.               je msts7
  1559.               mov si,offset menufile3       ; yes, text says FILE
  1560. msts7:        cmp menu_choice,2             ;is this the highlighted choice?
  1561.               je msts8
  1562.               call formline                 ; no, display normal
  1563.               jmp short msts9
  1564. msts8:        call cursline                 ; yes, display highlighted
  1565. msts9:
  1566.               cmp adapter,1                 ;enable CGA video
  1567.               jne msts10
  1568.               call enable_cga
  1569. msts10:
  1570.               pop es                        ;restore ES
  1571.               ret
  1572. make_status   endp
  1573. ;
  1574. ;------------------------------------------------------------------------------
  1575. ;MAKE_CHANGE changes the status of the redirection.
  1576. ;------------------------------------------------------------------------------
  1577. make_change   proc near
  1578.               push es                       ;save ES
  1579.  
  1580.               cmp menu_choice,0             ;is this the highlighted choice?
  1581.               jne mkchg1
  1582.               mov bx,offset lpt1            ;structure #1
  1583. mkchg1:
  1584.               cmp menu_choice,1             ;is this the highlighted choice?
  1585.               jne mkchg2
  1586.               mov bx,offset lpt2            ;structure #2
  1587. mkchg2:
  1588.               cmp menu_choice,2             ;is this the highlighted choice?
  1589.               jne mkchg3
  1590.               mov bx,offset lpt3            ;structure #3
  1591. mkchg3:
  1592.               cmp ds:[bx].active,OFF        ;flip printer redirection 
  1593.               je mkchg4
  1594.               mov ds:[bx].active,OFF        ;turn redirection OFF
  1595.               mov ax,ds:[bx].bufcntr        ;look at the buffer size
  1596.               or ah,al                      ;is there something in it ?
  1597.               jz mkchg5                     ; no, buffer was empty
  1598.               mov ds:[bx].request,ON        ; yes, request a buffer flush.
  1599.               jmp short mkchg5
  1600. mkchg4:       mov ax,ds:[bx].handle         ;get the file handle to check it
  1601.               or ah,al                      ;if it has ever been used.
  1602.               jz mkchg5                     ; no, don't activate
  1603.               mov ds:[bx].active,ON         ; yes, activate redirection
  1604. mkchg5:       call click                    ;give a little noisy feedback
  1605.               pop es                        ;restore ES
  1606.               ret
  1607. make_change   endp
  1608. ;
  1609. ;------------------------------------------------------------------------------
  1610. ;FORMLINE is called by MAKE_SCREEN to help with the dirty work.
  1611. ;------------------------------------------------------------------------------
  1612. formline      proc near
  1613.               mov ah,border_attr
  1614.               lodsb
  1615.               stosw
  1616.               mov cx,32                     ;do next 32 characters
  1617.               mov ah,text_attr
  1618. form1:        lodsb
  1619.               stosw
  1620.               loop form1
  1621.               mov ah,border_attr
  1622.               lodsb
  1623.               stosw
  1624.               ret
  1625. formline      endp
  1626. ;
  1627. ;
  1628. ;------------------------------------------------------------------------------
  1629. ;CURSLINE is called by MAKE_SCREEN to help with the dirty work.
  1630. ;------------------------------------------------------------------------------
  1631. cursline      proc near
  1632.               mov ah,border_attr
  1633.               lodsb
  1634.               stosw
  1635.               mov cx,32                     ;do next 32 characters
  1636.               mov ah,menu_attr
  1637. curs1:        lodsb
  1638.               stosw
  1639.               loop curs1
  1640.               mov ah,border_attr
  1641.               lodsb
  1642.               stosw
  1643.               ret
  1644. cursline      endp
  1645. ;
  1646. ;
  1647. ;------------------------------------------------------------------------------
  1648. ;DISABLE_CGA and ENABLE_CGA disable and enable CGA video output.
  1649. ;------------------------------------------------------------------------------
  1650. disable_cga   proc near
  1651.               mov dx,3DAh                   ;address of Status Register
  1652. disable1:     in al,dx                      ;get status
  1653.               test al,8                     ;vertical retrace active?
  1654.               je disable1                   ;no, then wait
  1655.               sub dx,2                      ;MSR address in DX
  1656.               mov al,25h                    ;value to disable video
  1657.               out dx,al                     ;disable video output
  1658.               ret
  1659. disable_cga   endp
  1660. ;
  1661. enable_cga    proc near
  1662.               mov ah,15                     ;get video mode
  1663.               int 10h
  1664.               mov bx,offset enable_values   ;get value to enable display
  1665.               xlat                          ;value in AL
  1666.               mov dx,3D8h                   ;MSR address
  1667.               out dx,al                     ;enable video output
  1668.               ret
  1669. enable_cga    endp
  1670. ;
  1671. ;------------------------------------------------------------------------------
  1672. ;GETKEY waits for a keypress and returns the keycode in AX.
  1673. ;Exit:  AX - keycode
  1674. ;This function is careful to generate int28 for other TSR that may need them
  1675. ;while the user is waiting to press a key.
  1676. ;------------------------------------------------------------------------------
  1677. getkey        proc near
  1678.               mov ah,1                      ;check keyboard buffer
  1679.               int 16h
  1680.               jne getkey1                   ;jump if buffer contains a keycode
  1681.               int 28h                       ;no key pressed - issue int 28h
  1682.               jmp getkey                    ;loop back to try again
  1683. getkey1:      mov ah,0                      ;get keycode from buffer
  1684.               int 16h
  1685.               ret                           ;exit with keycode in AX
  1686. getkey        endp
  1687. ;
  1688. ;
  1689. ;------------------------------------------------------------------------------
  1690. ;SHOW_CURSOR displays the cursor and discounts EGA cursor emulation logic.
  1691. ;Entry:  NEW_CURSOR - starting and ending scan lines
  1692. ;------------------------------------------------------------------------------
  1693. show_cursor   proc near
  1694.               cmp adapter,2                 ;is an EGA currently active?
  1695.               jne cursor1                   ;no, then branch
  1696.               push es                       ;save ES
  1697.               mov ax,bios_data              ;point ES to BIOS data area
  1698.               mov es,ax
  1699.               assume es:bios_data
  1700.               push infobyte                 ;save EGA info byte
  1701.               or ega_info,1                 ;disable EGA cursor emulation
  1702. cursor1:      mov ah,1                      ;display the cursor
  1703.               mov cx,new_cursor
  1704.               int 10h
  1705.               cmp adapter,2                 ;is an EGA active?
  1706.               jne cursor_exit               ;no, then exit
  1707.               pop infobyte                  ;restore EGA info byte
  1708.               pop es                        ;restore ES
  1709.               assume es:nothing
  1710. cursor_exit:  ret
  1711. show_cursor   endp
  1712. ;
  1713.  
  1714. ;--------------------------------------------------------------------
  1715. end_res db      0
  1716. ;
  1717. ; This is the end of the memory resident portion of LPTx
  1718. ;
  1719. ;--------------------------------------------------------------------
  1720. ;
  1721. ; All of the following data is in the Code Segment
  1722. ;
  1723. mach_type       db      0
  1724. DOS_version     db      0               ;Major Version Number
  1725.                 db      0               ;Minor Version Number
  1726. lfeed           db      ON              ;linefeed enable switch
  1727. appending       db      0               ;appending to an existing file
  1728. drive           db      0               ;default drive number 0=A etc.
  1729. flag_27         db      OFF             ; 1=make this copy resident
  1730. wrong_dos       db      'DOS 2.0 or later required for LPTx',LF,CR,DOLLAR
  1731. up_msg          db      'LPTx - Line Printer Redirection Program - V7.00'
  1732.                 db      LF,CR,'   Copyright 1987 Mark C. DiVecchio'
  1733.                 db      LF,CR,'   Copyright 1987 Kepa Zubeldia',LF,CR
  1734.                 db      DOLLAR
  1735. lptx_resident   db      LF,CR,'Resident Portion of LPTx Loaded',LF,CR
  1736.                 db      'The pop-up window will be activated by Alt-PrtSc'
  1737.                 db      LF,LF,CR
  1738.                 db      DOLLAR
  1739. lptx_err_3      db      'Could not delete file',LF,CR,DOLLAR
  1740. lptx_over       db      CR,LF,'File already exists. Do you want to overwrite '
  1741.                 db      'it? (y or n)  :',DOLLAR
  1742. lptx_nc         db      'File selection canceled',CR,LF,DOLLAR
  1743. lptx_lf         db      'Stripping Linefeed Characters',CR,LF,DOLLAR
  1744. lptx_sd_on      db      'Sound Enabled',CR,LF,DOLLAR
  1745. lptx_mono       db      'Monochrome only, graphic card ignored',CR,LF,DOLLAR
  1746. lptx_cs_off     db      'Critical Section Checking Disabled',CR,LF,DOLLAR
  1747. lptx_del        db      'File is being overwritten',LF,CR,DOLLAR
  1748. lptx_cr         db      LF,CR,DOLLAR
  1749. lptx_bad        db      'Invalid Option',LF,CR
  1750.                 db      'Calling sequence:',LF,CR
  1751.                 db      'lptx [?] [-m] [-x] [-l] [-i] {-1,-2,-3} {-c -o -a <d:[pathname]filename>}'
  1752.                 db      LF,CR,DOLLAR
  1753. lptx_on         db      LF,CR,'Redirection started. Disk file opened.'
  1754.                 db      LF,CR,DOLLAR
  1755. lptx_off        db      LF,CR,'Redirection ended. Disk file closed.'
  1756.                 db      LF,CR,DOLLAR
  1757. lptx_creat      db      'Could not create the disk file',LF,CR,DOLLAR
  1758. lptx_open       db      'Could not open the disk file',LF,CR,DOLLAR
  1759. lptx_gone       db      LF,'LPTx - Resident portion inactivated',CR,LF,DOLLAR
  1760. ; HELP screen
  1761. help_msg        db      LF,CR,'Calling sequence : ',LF,LF,CR
  1762.                 db      'LPTx [?] [-m] [-x] [-l] [-i] -p -f <[d:][\pathname\pathname]filename>'
  1763.                 db      LF,LF,CR
  1764.                 db      '    where  p = printer number : 1, 2, or 3',LF,CR
  1765.                 db      '           f = function : o for open a print file'
  1766.                 db      LF,CR
  1767.                 db      '                          a for append to a print file'
  1768.                 db      LF,CR
  1769.                 db      '                          c for close a print file'
  1770.                 db      LF,CR
  1771.                 db      '           drive letter & pathname are optional'
  1772.                 db      LF,CR
  1773.                 db      '           m = monochrome mode only, even with graphics cards'
  1774.                 db      LF,CR
  1775.                 db      '           x = disable check of Critical Section Flag'
  1776.                 db      LF,CR
  1777.                 db      '           l = strip Linefeed characters from output'
  1778.                 db      LF,CR
  1779.                 db      '           i = inactivate LPTx',LF,CR
  1780.                 db      '    defaults : p = 1',LF,CR
  1781.                 db      '               f = o',LF,CR
  1782.                 db      '    The pop-up window is activated with Alt-PrtSc'
  1783.                 db      LF,CR
  1784.                 db      DOLLAR
  1785. ;
  1786. stat_stat       db      CR,LF,'LPTx Status :',CR,LF,DOLLAR
  1787. stat_lp         db      'lpt'
  1788. stat_ptr        db      ' : ',DOLLAR
  1789. stat_off        db      ' not redirected',CR,LF,DOLLAR
  1790. stat_dir        db      ' redirected to disk file '
  1791. stat_fn         db      60 dup (BLANK)
  1792. ;
  1793. yn_max          db      2       ;max # of char
  1794. yn_act          db      0
  1795. yn_in           db      2 dup (0)
  1796. ;
  1797. ;--------------------------------------------------------------------
  1798. ;
  1799. ; This is the main routine which is executed each time that LPTx is 
  1800. ; called. In this routine, DS points to the data segment which is
  1801. ; transient. ES points to the data segment which is permanently
  1802. ; resident. ES:BX points to the data structure for the selected 
  1803. ; line printer, 1, 2, or 3.
  1804. ; The offsets are the same for both. If this is the first
  1805. ; time that LPTx is run, then ES=DS.
  1806. ;
  1807. lptx_start:
  1808.         push    DS                      ;Save DS
  1809.         xor     AX,AX                   ;clear AX for return IP
  1810.         push    AX                      ;put 0 on stack
  1811. ;
  1812. ;to check for machine type look at
  1813. ; F000:FFFE                             ; I don't use this currently
  1814. ;       = FF    IBM PC
  1815. ;       = FE    IBM XT or Portable
  1816. ;       = FD    IBM PCjr
  1817. ;       = FC    IBM PC AT
  1818. ;       = F9    IBM Convertible
  1819.         mov     AX,0F000h
  1820.         mov     ES,AX
  1821.         mov     BX,0FFFEh
  1822.         mov     CL,ES:[BX]              ;get machine type
  1823.         mov     mach_type,CL            ;save machine type
  1824. ;
  1825. ;PSP
  1826.         mov     lptx_psp,DS             ;put away our PSP Segment address
  1827. ;
  1828. ; get the DOS version number
  1829. ; returns zero for pre DOS 2.0 releases
  1830.         mov     AH,30h
  1831.         int     DOS_CALL                ;call DOS
  1832.         mov     word ptr DOS_version,AX 
  1833. ; Requires at least version 2.0 and may or may not work
  1834. ; with versions above 2.1
  1835.         cmp     DOS_version,2           ;is it DOS 2.+
  1836.         jge     dos_ok                  ;yes
  1837.         display wrong_dos               ;print error message
  1838.         mov     AH,0
  1839.         int     DOS_CALL                ;terminate
  1840. dos_ok: mov     AH,def_drive            ;get current default drive
  1841.         int     DOS_CALL
  1842.         mov     drive,AL                ;save the drive number
  1843.         display up_msg                  ;print program ID
  1844.         mov     flag_27,OFF             ;to not make resident
  1845. ; is a copy of LPTx already resident in memory?
  1846.         mov     DX,REQ                  ;check if LPTx is already resident
  1847.         mov     AH,3                    ;get status - special call
  1848.         int     17h                     ;call int 17h - BIOS
  1849.         cmp     DX,ACK                  ;my handler sets DX to ACK
  1850.                                         ;and sets ES 
  1851.         je      in_core                 ;LPTx is resident - ES loaded with
  1852.                                         ; segment address
  1853.         mov     flag_27,ON              ;to make this copy resident
  1854.         push    CS
  1855.         pop     ES                      ;set ES to CS for segment address
  1856.         mov     AL,drive
  1857.         add     AL,'a'                  ;make it a letter
  1858.         mov     BX,offset lpt1
  1859.         mov     ES:[BX].filen,AL        ;put it into the filename
  1860.         mov     BX,offset lpt2
  1861.         mov     ES:[BX].filen,AL        ;put it into the filename
  1862.         mov     BX,offset lpt3
  1863.         mov     ES:[BX].filen,AL        ;put it into the filename
  1864. ; ----------------------------------------------------
  1865. in_core:                                ;ES is ok
  1866. ; ES now points to resident data area
  1867. ; set up ES:BX to point to default data structure
  1868.         mov     BX,offset lpt1          ;offset - default to LPT1
  1869. ;get options and file name
  1870. ;scan input line for line printer number
  1871.         mov     SI,81h                  ;starting offset
  1872.         mov     CL,DS:80h               ;length of input line
  1873.         mov     CH,0
  1874.         cmp     CX,0                    ;nothing?
  1875.         jne     cont_scan               ;no
  1876.         jmp     make_res                ;yes, then just make LPTx resident
  1877.                                         ;if it isn't already
  1878.  
  1879. ;
  1880. ; [?]
  1881. ; HELP printer
  1882. ;
  1883. help:   display help_msg                ;display the HELP screen
  1884.         jmp     bail_out
  1885. ;
  1886. ; [-m]
  1887. ; Monochrome monitor, even on graphic card
  1888. ;
  1889. mono_only:
  1890.         mov     ES:nocolors,1
  1891.         display lptx_mono
  1892.         jmp     short inp_ret
  1893. ;
  1894. ; [-a]
  1895. ; appending to a file, similar to open.
  1896. ;
  1897. append:
  1898.         mov     appending,1
  1899.         jmp     file_op
  1900. ;
  1901. ;
  1902. cont_scan:
  1903.         cmp     byte ptr DS:[SI],'?'    ;a ?  ?
  1904.         je      help                    ;yes
  1905.         cmp     byte ptr DS:[SI],dash   ;a dash ?
  1906.         je      got_opt                 ;yes
  1907.         cmp     byte ptr DS:[SI],CR     ;a carriage return?
  1908.         je      scan_done               ;yes
  1909.         cmp     byte ptr DS:[SI],BLANK  ;a blank?
  1910.         je      inp_ret                 ;yes
  1911.         jmp     no_b                    ;assume that we got a file name
  1912.                                         ;without the -o option
  1913. inp_ret:
  1914.         inc     SI                      ;ignore blanks
  1915.         loop    cont_scan               ;continue to scan
  1916. ;
  1917. ; Scan of whole line is complete without a "-o", "-a", "-c" or filename
  1918. scan_done:
  1919.         jmp     make_res
  1920. ;
  1921. got_opt:                                ;we got an option
  1922.         inc     SI                      ;to option
  1923.         cmp     byte ptr DS:[SI],'1'    ;LPT1?
  1924.         jne     chk_2
  1925.         mov     BX,offset lpt1          ;offset from ES
  1926.         jmp     short inp_ret
  1927. chk_2:  cmp     byte ptr DS:[SI],'2'    ;LPT2?
  1928.         jne     chk_3
  1929.         mov     BX,offset lpt2          ;offset from ES
  1930.         jmp     short inp_ret
  1931. chk_3:  cmp     byte ptr DS:[SI],'3'    ;LPT3?
  1932.         jne     chk_fil
  1933.         mov     BX,offset lpt3          ;offset from ES
  1934.         jmp     short inp_ret
  1935. chk_fil:                                ;is it file?
  1936.         cmp     byte ptr DS:[SI],'?'    ;help ?
  1937.         je      help                    ;yes
  1938.         cmp     byte ptr DS:[SI],'o'    ;open a file
  1939.         je      file_op                 ;yes
  1940.         cmp     byte ptr DS:[SI],'a'    ;append to a file
  1941.         je      append                  ;yes
  1942.         cmp     byte ptr DS:[SI],'c'    ;close a file
  1943.         je      file_cl                 ;yes
  1944.         cmp     byte ptr DS:[SI],'m'    ;monochrome only ?
  1945.         je      mono_only               ;yes
  1946.         cmp     byte ptr DS:[SI],'x'    ;inhibit check for Critical Section?
  1947.         je      cs_check_off            ;yes
  1948.         cmp     byte ptr DS:[SI],'l'    ;linefeed switch ?
  1949.         je      lf_off                  ;yes
  1950.         cmp     byte ptr DS:[SI],'s'    ;enable sound?
  1951.         je      sound_on                ;yes
  1952.         cmp     byte ptr DS:[SI],'i'    ;inactivate?
  1953.         jne     bad_opt
  1954.         jmp     inactivate
  1955. bad_opt:
  1956.         display lptx_bad                ;incorrect option
  1957.         jmp     nor_ex
  1958. ;
  1959. ; [-x]
  1960. ; turn OFF Critical Section check
  1961. ;
  1962. cs_check_off:
  1963.         mov     ES:cs_switch,OFF
  1964.         display lptx_cs_off
  1965.         jmp     inp_ret
  1966. ;
  1967. ;[-l]
  1968. ; Turn linefeeds off in captured file
  1969. ;
  1970. lf_off: mov     lfeed,OFF               ;turn LFs off
  1971.         display lptx_lf
  1972.         jmp     inp_ret                 ;continue the scan
  1973. ;
  1974. ; [-s]
  1975. ; turn ON Sound
  1976. ;
  1977. sound_on:
  1978.         mov     ES:sound,ON
  1979.         display lptx_sd_on
  1980.         jmp     inp_ret
  1981. ;
  1982. ; [-c]
  1983. ; close output file
  1984. ;
  1985. file_cl:cmp     ES:[BX].active,ON       ;are we active?
  1986.         jne     no_close                ;no
  1987.         mov     AL,1AH                  ;CTRL-Z
  1988.         push    DS
  1989.         push    ES
  1990.         pop     DS                      ;set DS to point to resident
  1991.                                         ;data segment
  1992. ;       call    prnt                    ;print end of file mark
  1993.         call    flush
  1994.         pop     DS                      ;restore DS
  1995.         mov     ES:[BX].active,OFF      ;make us inactive
  1996.         display lptx_off                ;redirection off message
  1997. no_close:
  1998.         jmp     nor_exit                ;nothing to close so exit
  1999. ;
  2000. ; [-o]
  2001. ; open a file for ouput
  2002. ;
  2003. file_op:                                ;get the file name
  2004.         inc     SI                      ;to next chracter
  2005.         cmp     byte ptr DS:[SI],BLANK  ;a blank?
  2006.         jne     no_b                    ;no
  2007.         inc     SI                      ;skip over blank
  2008. no_b:
  2009. ; at this point, we have found a new file name. We close the old
  2010. ; file if one was open
  2011.         cmp     ES:[BX].active,ON       ;are we active?
  2012.         jne     no_cl                   ;no
  2013.         mov     AL,1AH                  ;CTRL-Z
  2014.         push    DS
  2015.         push    ES
  2016.         pop     DS                      ;set DS to point to resident
  2017.                                         ;data segment
  2018. ;       call    prnt                    ;print end of file mark
  2019.         call    flush
  2020.         pop     DS                      ;restore DS
  2021.         mov     ES:[BX].active,OFF      ;make us inactive
  2022.         display lptx_off                ;redirection off message
  2023. no_cl:  mov     DI,BX                   ;base of structure
  2024.         add     DI,offset lpt1.filen    ;add offset of destination
  2025.         push    SI                      ;save pointer to file name
  2026. ; search for a drive letter
  2027.         inc     SI                      ;should point to a colon if
  2028.                                         ;one is there
  2029.         cmp     byte ptr [SI],COLON     ;?
  2030.         je      got_drive               ;yes
  2031. get_drive:
  2032.         mov     AL,drive                ;get drive letter
  2033.         add     AL,'a'                  ;make it a letter
  2034.         mov     ES:[DI],AL              ;put it in file name
  2035.         inc     DI
  2036.         mov     byte ptr ES:[DI],COLON  ;put in a colon
  2037.         inc     DI
  2038.         jmp     path_search
  2039. got_drive:
  2040.         pop     SI                      ;move pointer back to start
  2041.         mov     AL,[SI]                 ;get the given drive
  2042.         mov     ES:[DI],AL              ;move it
  2043.         sub     AL,'a'                  ;make it a number
  2044.         mov     drive,AL                ;save the drive number
  2045.         inc     SI
  2046.         inc     DI
  2047.         mov     byte ptr ES:[DI],COLON
  2048.         inc     DI
  2049.         inc     SI
  2050.         push    SI                      ;save new start pointer
  2051. path_search:
  2052. ; now search for a backslash which says that a pathname was given
  2053. bk_s_lp:cmp     byte ptr [SI],BACKSLASH
  2054.         je      got_path                ;a path
  2055.         cmp     byte ptr [SI],CR        ;end of the file name?
  2056.         je      get_path                ;yes with no path
  2057.         inc     SI
  2058.         jmp     short bk_s_lp           ;loop
  2059. get_path:
  2060.         mov     byte ptr ES:[DI],BACKSLASH      ;create the path
  2061.         inc     DI
  2062.         mov     DL,drive                ;the current drive
  2063.         inc     DL                      ;bump it for DOS
  2064.         push    DS
  2065.         push    ES
  2066.         pop     DS                      ;set up DS for DOS
  2067.         mov     SI,DI                   ;set up SI for pathname
  2068.         mov     AH,def_path             ;get current directory
  2069.         int     DOS_CALL                ;path goes into DS:SI
  2070.         pop     DS                      ;restore DS
  2071.         cmp     byte ptr ES:[SI],NULL   ;null path?
  2072.         je      null_path               ;yes - root directory
  2073. path_lp:                                ;now find the end of the string
  2074.         cmp     byte ptr ES:[SI],NULL   ;null byte marks end of pathname
  2075.         je      end_path                ;now append the file name
  2076.         inc     SI
  2077.         jmp     short path_lp
  2078. end_path:
  2079.         mov     byte ptr ES:[SI],BACKSLASH
  2080.         inc     SI
  2081. null_path:
  2082.         mov     DI,SI                   ;DI is destination
  2083. got_path:
  2084.         pop     SI                      ;restore source of filename
  2085. ; pick up everything to next blank
  2086. get_lp:
  2087.         mov     AL,DS:[SI]              ;character
  2088.         mov     ES:[DI],AL              ;put it away
  2089.         cmp     AL,CR                   ;was it a Carriage Return?
  2090.         je      end_line
  2091.         cmp     AL,BLANK                ;was it a space?
  2092.         je      end_line
  2093.         inc     SI
  2094.         inc     DI
  2095.         jmp     short get_lp            ;no so get next character
  2096. end_line:
  2097.         mov     byte ptr ES:[DI],NULL   ;zero out the CR or blank
  2098.                                         ;at the end of the filename
  2099.                                         ;it becomes an ASCIIZ string
  2100.         sub     DI,BX                   ;now take out the base and
  2101.         cmp     DI,offset lpt1.filen    ; make sure that we got something
  2102.         jne     lptx_make               ;file name was ok
  2103.         display lptx_creat              ;could not understand the file name
  2104.         jmp     nor_exit                ;don't stay resident
  2105. nor_ex: jmp     nor_exit
  2106.  
  2107. lptx_make:
  2108. ; default DTA used by Find File is set by DOS to an offset of
  2109. ; 80h into this program's Program Segment Prefix
  2110.  push DS
  2111.         push    ES
  2112.         pop     DS                      ;uses DS:DX
  2113.         mov     DX,BX
  2114.         add     DX,offset lpt1.filen    ;file name
  2115.         mov     AH,find_FILE
  2116.         mov     CX,0                    ;normal files only
  2117.         int     DOS_CALL                ;find first match
  2118.         pop     DS
  2119.         jnc     lptx_d                  ;file was found
  2120.         jmp     lptx_create             ;not there - which is ok
  2121. ;file already exists
  2122. lptx_d: cmp     appending,1             ;are we in append mode?
  2123.         je      lptx_x                  ; yes
  2124.         display lptx_over
  2125.         mov     DX,offset yn_max;input buffer
  2126.         mov     AH,0AH
  2127.         int     DOS_CALL
  2128.         cmp     yn_act,0                ;anything typed?
  2129.         display lptx_cr
  2130.         je      lptx_x                  ;no - try to append
  2131.         cmp     yn_in,'y'               ;a yes?
  2132.         je      lptx_d_yes              ;yes
  2133.         cmp     yn_in,'Y'               ;a yes?
  2134.         je      lptx_d_yes              ;yes
  2135. lptx_x: push    DS                      ;we can't overwrite, try to append
  2136.         push    ES
  2137.         pop     DS                      ;uses DS:DX
  2138.         mov     DX,BX                   ;base of this LPT's structure
  2139.         add     DX,offset lpt1.filen    ;file name
  2140.         mov     AL,1                    ;open for writing
  2141.         mov     AH,open_FILE
  2142.         mov     CX,0                    ;normal files only
  2143.         int     DOS_CALL                ;find first match
  2144.         pop     DS
  2145.         jnc     creat_ok
  2146.         display lptx_open               ;could not open the file
  2147.         display lptx_nc
  2148.         jmp     nor_exit                ;don't stay resident
  2149.  
  2150. lptx_d_yes:
  2151.         display lptx_del
  2152.         push    DS
  2153.         push    ES
  2154.         pop     DS                      ;uses DS:DX
  2155.         mov     DX,BX
  2156.         add     DX,offset lpt1.filen    ;file name
  2157.         mov     AH,delete_FILE
  2158.         int     DOS_CALL                ;delete file
  2159.         pop     DS
  2160.         jnc     lptx_create             ;ok its gone
  2161.         display lptx_err_3              ;can't delete it
  2162.         jmp     nor_exit
  2163. lptx_create:                            ; create the file
  2164.         push    DS
  2165.         push    ES
  2166.         pop     DS                      ;uses DS:DX
  2167.         mov     DX,BX                   ;base of this LPT's structure
  2168.         add     DX,offset lpt1.filen    ;file name
  2169.         mov     AH,create_FILE
  2170.         mov     CX,0                    ;normal files only
  2171.         int     DOS_CALL                ;find first match
  2172.         pop     DS
  2173.         jnc     creat_ok
  2174.         display lptx_creat              ;could not create the file
  2175.         jmp     nor_exit                ;don't stay resident
  2176. creat_ok:                               ;now close the file
  2177.         push    BX
  2178.         mov     ES:[BX].handle,AX       ;save the handle, for popup to know.
  2179.         mov     BX,AX                   ;AX was loaded by the create file
  2180.                                         ;       call
  2181.         mov     AH,close_FILE           ;close the file
  2182.         int     DOS_CALL
  2183.         pop     BX
  2184.         display lptx_on
  2185. ; set the program up for writing
  2186.         mov     ES:[BX].bufcntr,EMPTY   ;set buffer empty
  2187.         mov     ES:[BX].active,ON       ;set us on
  2188.         mov     AL,lfeed
  2189.         mov     ES:[BX].linefeed,AL     ;save linefeed switch
  2190. make_res:
  2191.         cmp     flag_27,ON              ;make this one resident?
  2192.         je      resident                ;yes
  2193.         jmp     nor_exit                ;no
  2194. ;
  2195. resident:
  2196.         push    ES
  2197.         push    BX
  2198. ; get old interrupt handler addressses
  2199.         mov     AL,17h                  ;get current vector address for 17h
  2200.         mov     AH,35h
  2201.         int     DOS_CALL
  2202.         mov     word ptr old_17h,BX
  2203.         mov     word ptr old_17h[2],ES  ;save it for later use
  2204.  
  2205.         mov     AL,08h                  ;get current vector address for 08h
  2206.         mov     AH,35h
  2207.         int     DOS_CALL
  2208.         mov     word ptr old_08h,BX
  2209.         mov     word ptr old_08h[2],ES  ;save it for later use
  2210.  
  2211.         mov     AL,09h                  ;get current vector address for 09h
  2212.         mov     AH,35h
  2213.         int     DOS_CALL
  2214.         mov     word ptr old_09h,BX
  2215.         mov     word ptr old_09h[2],ES  ;save it for later use
  2216.  
  2217.         mov     AL,10h                  ;get current vector address for 10h
  2218.         mov     AH,35h
  2219.         int     DOS_CALL
  2220.         mov     word ptr old_10h,BX
  2221.         mov     word ptr old_10h[2],ES  ;save it for later use
  2222.  
  2223.         mov     AL,13h                  ;get current vector address for 13h
  2224.         mov     AH,35h
  2225.         int     DOS_CALL
  2226.         mov     word ptr old_13h,BX
  2227.         mov     word ptr old_13h[2],ES  ;save it for later use
  2228.  
  2229.         mov     AL,DOS_CALL             ;get current vector address for 21h
  2230.         mov     AH,35h
  2231.         int     DOS_CALL
  2232.         mov     word ptr old_21h,BX
  2233.         mov     word ptr old_21h[2],ES  ;save it for later use
  2234.  
  2235.         mov     AL,28h                  ;get current vector address for 28h
  2236.         mov     AH,35h
  2237.         int     DOS_CALL
  2238.         mov     word ptr old_28h,BX
  2239.         mov     word ptr old_28h[2],ES  ;save it for later use
  2240.  
  2241. ;
  2242. ; Set LPTx up as the new int 17h interrupt handler
  2243.         mov     AX,2517h                ;set interrupt vector
  2244.         mov     DX,offset int_17h       ;BIOS printer
  2245.         int     DOS_CALL
  2246. ;
  2247. ; Set LPTx up as the new int 08h interrupt handler
  2248.         mov     AX,2508h                ;set interrupt vector
  2249.         mov     DX,offset int_08h       ;Timer
  2250.         int     DOS_CALL
  2251. ;
  2252. ; Set LPTx up as the new int 09h interrupt handler
  2253.         mov     AX,2509h                ;set interrupt vector
  2254.         mov     DX,offset keyboard      ;Keyboard
  2255.         int     DOS_CALL
  2256. ;
  2257. ; Set LPTx up as the new int 10h interrupt handler
  2258.         mov     AX,2510h                ;set interrupt vector
  2259.         mov     DX,offset video         ;Video
  2260.         int     DOS_CALL
  2261. ;
  2262. ; Set LPTx up as the new int 13h interrupt handler
  2263.         mov     AX,2513h                ;set interrupt vector
  2264.         mov     DX,offset bdisk         ;Disk
  2265.         int     DOS_CALL
  2266. ;
  2267. ; Set LPTx up as the new int 21h interrupt handler
  2268. ;       mov     AX,2521h                ;set interrupt vector
  2269. ;       mov     DX,offset int_21h       ;DOS Functions
  2270. ;       int     DOS_CALL
  2271. ;
  2272. ; Set LPTx up as the new int 28h interrupt handler
  2273.         mov     AX,2528h                ;set interrupt vector
  2274.         mov     DX,offset int_28h       ;Idle
  2275.         int     DOS_CALL
  2276. ;
  2277. ; get the address of the critical section flag
  2278. ;
  2279.         mov     AH,34h
  2280.         int     DOS_CALL                ;Call Special DOS interrupt
  2281.                                         ;returns pointer to critical
  2282.                                         ;section flag in ES:BX
  2283.                                         ;With DOS 2.1, this returns
  2284.                                         ;00EC:012D. I used the XRAY
  2285.                                         ;program to look at this
  2286.                                         ;byte while DOS was running.
  2287.         mov     csect_seg,ES            ;save the pointer
  2288.         mov     csect_off,BX
  2289. ;
  2290. ; get the address of the critical error flag. This piece of code comes from
  2291. ; PC Magazine, October 13, 1987, page 416, CARDFILE.ASM, by Jeff Prosise.
  2292. ;
  2293.               mov cerrf_seg,ES              ;save the pointer for critical error
  2294.               mov ax,3E80h                  ;CMP opcode
  2295.               mov cx,2000h                  ;max search length
  2296.               mov di,bx                     ;start at critical section address
  2297. ce_init4:     repne scasw                   ;do the search
  2298.               jcxz ce_init5                 ;branch if search failed
  2299.               cmp byte ptr es:[di+5],0BCh   ;verify this is it
  2300.               je ce_found                   ;branch if it is
  2301.               jmp ce_init4                  ;resume loop if it's not
  2302. ce_init5:     mov cx,2000h                  ;search again
  2303.               inc bx                        ;search odd addresses this time
  2304.               mov di,bx
  2305. ce_init6:     repne scasw                   ;look for the opcode
  2306.               jcxz ce_notfound              ;not found if loop expires
  2307.               cmp byte ptr es:[di+5],0BCh   ;verify this is it
  2308.               je ce_found
  2309.               jmp ce_init6
  2310. ce_notfound:  mov ax,csect_off              ;flag not found, fake it
  2311.               jmp ce_end
  2312. ce_found:     mov ax,es:[di]                ;get flag offset address
  2313. ce_end:       mov cerrf_off,ax              ;save it
  2314. ;
  2315.         pop     BX
  2316.         pop     ES
  2317.         display lptx_resident           ;resident loaded message
  2318.         call    stat                    ;display status
  2319.         mov     DX,offset end_res
  2320.         int     27h                     ;terminate but stay resident
  2321. ;
  2322. ; Normal exit for transient copy of LPTx
  2323. nor_exit:
  2324.         call    stat                    ;display status
  2325. bail_out:
  2326.         mov     AH,0
  2327.         int     DOS_CALL                ;terminate
  2328. ;
  2329. ; [-i]
  2330. ; unhook LPTx from interrupt vectors 08h, 09h, 17h, 21h, and 28h
  2331. inactivate:
  2332. ;
  2333.         cmp     word ptr ES:old_17h,0   ;is it sill 0?
  2334.         je      bail_out                ;yes, we weren't installed yet
  2335. ; flush all buffers
  2336.         mov     BX,offset lpt1
  2337.         cmp     ES:[BX].active,ON       ;are we active?
  2338.         jne     no_cl1                  ;no
  2339.         mov     AL,1AH                  ;CTRL-Z
  2340.         push    DS
  2341.         push    ES
  2342.         pop     DS                      ;set DS to point to resident
  2343.                                         ;data segment
  2344. ;       call    prnt                    ;print end of file mark
  2345.         call    flush
  2346.         pop     DS                      ;restore DS
  2347.         mov     ES:[BX].active,OFF      ;make us inactive
  2348.         display lptx_off                ;capturing off message
  2349. ;
  2350. no_cl1:
  2351.         mov     BX,offset lpt2
  2352.         cmp     ES:[BX].active,ON       ;are we active?
  2353.         jne     no_cl2                  ;no
  2354.         mov     AL,1AH                  ;CTRL-Z
  2355.         push    DS
  2356.         push    ES
  2357.         pop     DS                      ;set DS to point to resident
  2358.                                         ;data segment
  2359. ;       call    prnt                    ;print end of file mark
  2360.         call    flush
  2361.         pop     DS                      ;restore DS
  2362.         mov     ES:[BX].active,OFF      ;make us inactive
  2363.         display lptx_off                ;capturing off message
  2364. ;
  2365. no_cl2:
  2366.         mov     BX,offset lpt3
  2367.         cmp     ES:[BX].active,ON       ;are we active?
  2368.         jne     no_cl3                  ;no
  2369.         mov     AL,1AH                  ;CTRL-Z
  2370.         push    DS
  2371.         push    ES
  2372.         pop     DS                      ;set DS to point to resident
  2373.                                         ;data segment
  2374. ;       call    prnt                    ;print end of file mark
  2375.         call    flush
  2376.         pop     DS                      ;restore DS
  2377.         mov     ES:[BX].active,OFF      ;make us inactive
  2378.         display lptx_off                ;capturing off message
  2379. no_cl3:
  2380.         push    DS
  2381.         mov     DX,word ptr ES:old_17h  ;original vector, offset
  2382.         mov     AX,word ptr ES:old_17h[2];original vector, segment
  2383.         mov     DS,AX
  2384.         mov     AX,2517h                ;set interrupt vector to DS:DX
  2385.         int     DOS_CALL
  2386.         pop     DS
  2387.  
  2388.         push    DS
  2389.         mov     DX,word ptr ES:old_21h  ;original vector, offset
  2390.         mov     AX,word ptr ES:old_21h[2];original vector, segment
  2391.         mov     DS,AX
  2392.         mov     AX,2521h                ;set interrupt vector to DS:DX
  2393.         int     DOS_CALL
  2394.         pop     DS
  2395.  
  2396.  
  2397.         push    DS
  2398.         mov     DX,word ptr ES:old_08h  ;original vector, offset
  2399.         mov     AX,word ptr ES:old_08h[2];original vector, segment
  2400.         mov     DS,AX
  2401.         mov     AX,2508h                ;set interrupt vector to DS:DX
  2402.         int     DOS_CALL
  2403.         pop     DS
  2404.  
  2405.  
  2406.         push    DS
  2407.         mov     DX,word ptr ES:old_09h  ;original vector, offset
  2408.         mov     AX,word ptr ES:old_09h[2] ;original vector, segment
  2409.         mov     DS,AX
  2410.         mov     AX,2509h                ;set interrupt vector to DS:DX
  2411.         int     DOS_CALL
  2412.         pop     DS
  2413.  
  2414.  
  2415.         push    DS
  2416.         mov     DX,word ptr ES:old_10h  ;original vector, offset
  2417.         mov     AX,word ptr ES:old_10h[2] ;original vector, segment
  2418.         mov     DS,AX
  2419.         mov     AX,2510h                ;set interrupt vector to DS:DX
  2420.         int     DOS_CALL
  2421.         pop     DS
  2422.  
  2423.  
  2424.         push    DS
  2425.         mov     DX,word ptr ES:old_13h  ;original vector, offset
  2426.         mov     AX,word ptr ES:old_13h[2] ;original vector, segment
  2427.         mov     DS,AX
  2428.         mov     AX,2513h                ;set interrupt vector to DS:DX
  2429.         int     DOS_CALL
  2430.         pop     DS
  2431.  
  2432.  
  2433.         push    DS
  2434.         mov     DX,word ptr ES:old_28h  ;original vector, offset
  2435.         mov     AX,word ptr ES:old_28h[2];original vector, segment
  2436.         mov     DS,AX
  2437.         mov     AX,2528h                ;set interrupt vector to DS:DX
  2438.         int     DOS_CALL
  2439.         pop     DS
  2440.  
  2441.         display lptx_gone               ;inactivated
  2442.         jmp     bail_out
  2443. ;------------------------------------------------------------------------
  2444. ;
  2445. ; displays the status of each of the three line printers
  2446. ;
  2447. stat    proc    near
  2448. ; display each LPTx with a message "not redirected"
  2449. ;                       or redirected to <filename>
  2450.         push    AX
  2451.         push    BX
  2452.         push    DX
  2453.         push    SI
  2454.         push    DI
  2455.         display stat_stat
  2456. stat_1: mov     BX,offset lpt1          ;first printer
  2457.         mov     stat_ptr,'1'
  2458.         display stat_lp
  2459.         cmp     ES:[BX].active,ON       ;are we active?
  2460.         je      stat_1_a                ;yes
  2461.         display stat_off
  2462.         jmp     short stat_2
  2463. stat_1_a:
  2464.         mov     SI,BX                   ;base
  2465.         add     SI,offset lpt1.filen    ;offset
  2466.         mov     DI,offset stat_fn
  2467. stat_1_lp:
  2468.         mov     AL,ES:[SI]
  2469.         mov     [DI],AL
  2470.         inc     SI
  2471.         inc     DI
  2472.         cmp     AL,NULL                 ;loop till a null byte is found
  2473.         jne     stat_1_lp
  2474.         mov     byte ptr [DI],CR
  2475.         inc     DI
  2476.         mov     byte ptr [DI],LF
  2477.         inc     DI
  2478.         mov     byte ptr [DI],DOLLAR
  2479.         display stat_dir                ;display file name
  2480. stat_2:
  2481.         mov     BX,offset lpt2          ;second printer
  2482.         mov     stat_ptr,'2'
  2483.         display stat_lp
  2484.         cmp     ES:[BX].active,ON       ;are we active?
  2485.         je      stat_2_a                ;yes
  2486.         display stat_off
  2487.         jmp     short stat_3
  2488. stat_2_a:
  2489.         mov     SI,BX                   ;base
  2490.         add     SI,offset lpt1.filen    ;offset
  2491.         mov     DI,offset stat_fn
  2492. stat_2_lp:
  2493.         mov     AL,ES:[SI]
  2494.         mov     [DI],AL
  2495.         inc     SI
  2496.         inc     DI
  2497.         cmp     AL,NULL                 ;loop till a null byte is found
  2498.         jne     stat_2_lp
  2499.         mov     byte ptr [DI],CR
  2500.         inc     DI
  2501.         mov     byte ptr [DI],LF
  2502.         inc     DI
  2503.         mov     byte ptr [DI],DOLLAR
  2504.         display stat_dir                ;display file name
  2505. stat_3: mov     BX,offset lpt3          ;third printer
  2506.         mov     stat_ptr,'3'
  2507.         display stat_lp
  2508.         cmp     ES:[BX].active,ON       ;are we active?
  2509.         je      stat_3_a                ;yes
  2510.         display stat_off
  2511.         jmp     short stat_done
  2512. stat_3_a:
  2513.         mov     SI,BX                   ;base
  2514.         add     SI,offset lpt1.filen    ;offset
  2515.         mov     DI,offset stat_fn
  2516. stat_3_lp:
  2517.         mov     AL,ES:[SI]
  2518.         mov     [DI],AL
  2519.         inc     SI
  2520.         inc     DI
  2521.         cmp     AL,NULL                 ;loop till a null byte is found
  2522.         jne     stat_3_lp
  2523.         mov     byte ptr [DI],CR
  2524.         inc     DI
  2525.         mov     byte ptr [DI],LF
  2526.         inc     DI
  2527.         mov     byte ptr [DI],DOLLAR
  2528.         display stat_dir                ;display file name
  2529. stat_done:
  2530.         pop     DI
  2531.         pop     SI
  2532.         pop     DX
  2533.         pop     BX
  2534.         pop     AX
  2535.         ret
  2536. stat    endp
  2537. ;
  2538. cseg    ends
  2539. %out EOF
  2540.         end     lptx
  2541.  
  2542.